用相应列中提供的文件的数字相应第 n 行替换两个不同列上第 n 次出现的 'foo' 和 'bar'

Question

我有一个如下所示的source.txt 文件，其中包含两列数据。 source.txt的列格式包括[]（方括号）如我的source.txt所示：

[hot] [water]
[16] [boots and, juice]

我还有另一个 target.txt 文件，其中包含空行以及每行末尾的句号：

the weather is today (foo) but we still have (bar). 

= (

the next bus leaves at (foo) pm, we can't forget to take the (bar).

我想用source.txt的第一列的“相应内容”替换target.txt的每n行的foo，并替换每nth的bar target.txt 的行与source. txt 的第二列 的“相应内容”。

我试图搜索其他来源并了解我将如何做到这一点，起初我已经有一个用于替换 "replace each nth occurrence of 'foo' by numerically respective nth line of a supplied file" 的命令，但我无法适应它：

awk 'NR==FNR {a[NR]=$0; next} /foo/{gsub("foo", a[++i])} 1' source.txt target.txt > output.txt;

我记得看到过一种使用 gsub 包含两列数据的方法，但我不记得具体有什么区别。

编辑帖子：有时会在 target.txt 文本中读取 = 和 ( 和 ) 之间的一些符号。我添加了这个符号，因为如果这些符号在 target.txt 文件中，某些答案将不起作用

注意：target.txt 的行数以及 bar 和 foo 在此文件中的出现次数可能会有所不同，我只是展示了一个示例。但是foo和bar在每一行中出现的次数分别为1。

Answer 1

使用您显示的示例，请尝试以下答案。用 GNU awk 编写和测试。

awk -F'\\[|\\] \\[|\\]' '
FNR==NR{
  foo[FNR]=$2
  bar[FNR]=$3
  next
}
NF{
  gsub(/\<foo\>/,foo[++count])
  gsub(/\<bar\>/,bar[count])
}
1
' source.txt FS=" " target.txt

说明：为上述添加详细说明。

awk -F'\\[|\\] \\[|\\]' '       ##Setting field separator as [ OR ] [ OR ] here.
FNR==NR{                        ##Checking condition FNR==NR which will be TRUE when source.txt will be read.
  foo[FNR]=$2                   ##Creating foo array with index of FNR and value of 2nd field here.   
  bar[FNR]=$3                   ##Creating bar array with index of FNR and value of 3rd field here.
  next                          ##next will skip all further statements from here.
}
NF{                             ##If line is NOT empty then do following.
  gsub(/\<foo\>/,foo[++count])  ##Globally substituting foo with array foo value, whose index is count.
  gsub(/\<bar\>/,bar[count])    ##Globally substituting bar with array of bar with index of count.
}
1                               ##printing line here.
' source.txt FS=" " target.txt  ##Mentioning Input_files names here.

---

---

编辑：还添加以下解决方案，该解决方案将处理源中出现 n 次 [...] 并在目标文件中匹配它们。因为这是 OP（在 cmets 中确认）的工作解决方案，所以在此处添加。同样公平的警告，当 source.txt 包含 & 时，这将失败。

awk '
FNR==NR{
  while(match($0,/\[[^]]*\]/)){
    arr[++count]=substr($0,RSTART+1,RLENGTH-2)
    $0=substr($0,RSTART+RLENGTH)
  }
  next
}
{
  line=$0
  while(match(line,/\(?[[:space:]]*(\<foo\>|\<bar\>)[[:space:]]*\)?/)){
    val=substr(line,RSTART,RLENGTH)
    sub(val,arr[++count1])
    line=substr(line,RSTART+RLENGTH)
  }
}
1
' source.txt target.txt

Answer 2

在每个 Unix 机器上的任何 shell 中使用任何 awk：

$ cat tst.awk
BEGIN {
    FS="[][]"
    tags["foo"]
    tags["bar"]
}
NR==FNR {
    map["foo",NR] = $2
    map["bar",NR] = $4
    next
}
{
    found = 0
    head = ""
    while ( match($0,/\([^)]+)/) ) {
        tag = substr($0,RSTART+1,RLENGTH-2)
        if ( tag in tags ) {
            if ( !found++ ) {
                lineNr++
            }
            val = map[tag,lineNr]
        }
        else {
            val = substr($0,RSTART,RLENGTH)
        }
        head = head substr($0,1,RSTART-1) val
        $0 = substr($0,RSTART+RLENGTH)
    }
    print head $0
}

$ awk -f tst.awk source.txt target.txt
the weather is today hot but we still have water.

= (

the next bus leaves at 16 pm, we can't forget to take the boots and, juice.

Answer 3

awk '
    NR==FNR { # build lookup

        # delete gumph
        gsub(/(^[[:space:]]*\[)|(\][[:space:]]*$)/, "")

        # split
        split($0, a, /\][[:space:]]+\[/)

        # store
        foo[FNR] = a[1]
        bar[FNR] = a[2]

        next
    }

    !/[^[:space:]]/ { next } # ignore blank lines

    { # do replacements
        VFNR++ # FNR - (ignored lines)

        # can use sub if foo/bar only appear once
        gsub(/\<foo\>/, foo[VFNR])
        gsub(/\<bar\>/, bar[VFNR])

        print
    }
' source.txt target.txt

注意：\< 和 \> 不在 POSIX 中，但被某些版本的 awk（例如 gawk）所接受。我不确定 POSIX awk 正则表达式是否有“单词边界”。