为什么我的 Java 程序没有从 Arduino 获取串行信息？

Question

import processing.serial.*;
int newval = 0;      //Varible for feeding values onto the end of the 
Serial myPort;
String temp = "0";   //Temporary varible for pulling Strings off the serial connection
float[] vals;        //Array of data to be graphed

void setup() {
  //Setting up size and the serial port
  size(1920,1080);
  smooth();
  String portName = Serial.list()[0];
  myPort = new Serial(this, portName, 9600);

  //Initilizing vals 
  vals = new float [width];

  //Setting everything in vals to 0
  for (int i = 0; i < vals.length - 1;i++)
  {
    vals [i] = 0;
  }

}


void draw() {

  background(0);

  //Drawing function
  for (int i = 0; i < vals.length - 1; i += 1)
  {
    stroke(255);
    strokeWeight(1);
    line(i,vals[i], i+1, vals[i+1]);
  }

  //Push everything in vals back one slot
  for (int i = 0; i < vals.length - 1; i++)
  {
    vals[i] = vals[i+1];
  }

  //Pull data from the serial connection
  if ( myPort.available() > 0) 
  {
    temp = (new String(myPort.readBytesUntil('\n'))).trim(); //Take a string off of the serial 
                                                             //port and remove any spaces
    newval = Integer.parseInt(temp);                         //Convert temp to an integer
  }

  vals[vals.length - 1] = newval;                            //Set the last space in vals to newval
  println(newval);                                           //Print newval for debugging purposes

}

上面是我正在使用的代码。

我已经连接了我的Arduino to a potentiometer，然后将其连接到一个模拟输入引脚，从而有效地创建了一个variable voltage divider。此代码成功提取了第一个整数数据，并将其绘制为连续水平线，未能获取任何其他数据。我已经检查过了，它确实输入了if (myPort.availible > 0 )，但newval 没有改变。 Arduino 表现完美，我通过 Arduino IDE 检查了串行数据，看起来表现良好，因此它一定是程序问题。请帮忙！

编辑：我一直在努力。一个建议是实现一个 serialevent 函数。这产生了相同的结果。

Arduino 代码：

#define PIN A0

void setup()
{
  Serial.begin(9600);
}

void loop ()
{
  Serial.print(analogRead(PIN));
  Serial.print('\n');
}

新的（工作的）Arduino 代码：

#define PIN A0

void setup()
{
  Serial.begin(9600);
}

void loop ()
{
  Serial.print(analogRead(PIN));
  Serial.print('\n');
  delay(20);
}

Answer 1

我不知道串行编程是如何工作的。但我想我看到了一个可能出现这个问题的地方：

temp = (new String(myPort.readBytesUntil('\n'))).trim();

这里，readBytesUntil 实际上试图找到换行符。如果找不到字符，则返回null。

如果temp 有空值，newval 会导致空指针异常。 尝试在 if 循环周围放置一个 try catch 块，如下所示：

try
{
  if ( myPort.available() > 0) 
  {
    temp = (new String(myPort.readBytesUntil('\n'))).trim();   //Take a string off of the serial     
                                                                 port and remove any spaces
    newval = Integer.parseInt(temp);                            //Convert temp to an integer
  }
}
catch(NullPointerException e)
{
 e.printStackTrace();
}

现在如果你遇到空指针异常，这意味着你的端口没有'\n'字符 您希望解析的可能字符串的结尾。在这种情况下，我想您必须在推送数据时自愿添加换行符。

我真的对端口和东西一无所知。但如果以上描述能帮助您摆脱问题，我会很高兴。

Answer 2

您可以尝试使用serialEvent 吗？

import processing.serial.*;
int newval = 0;      //Varible for feeding values onto the end of the 
Serial myPort;
String temp = "0";   //Temporary varible for pulling Strings off the serial connection
float[] vals;        //Array of data to be graphed

void setup() {
  //Setting up size and the serial port
  size(1920,1080);
  smooth();
  stroke(255);
  strokeWeight(1);
  try{
    String portName = Serial.list()[0];
    myPort = new Serial(this, portName, 9600);
    myPort.bufferUntil(10);//ASCII linefeed 
  }catch(Exception e){
    System.err.println("Error opening serial device\nPlease check if the device is connected !");
  }
  //Initilizing vals 
  vals = new float [width];//initializez with 0s by default

}


void draw() {
  background(0);

  //Drawing function
  for (int i = 0; i < vals.length - 1; i ++)
  {
    line(i,vals[i], i+1, vals[i+1]);
  }


}

void serialEvent(Serial p) { 
  try{
    //Push everything in vals back one slot
    for (int i = 0; i < vals.length - 1; i++)
    {
      vals[i] = vals[i+1];
    }

    temp = p.readString().trim(); 
    newval = Integer.parseInt(temp);

    vals[vals.length - 1] = newval;                              //Set the last space in vals to newval
    println(newval);                                             //Print newval for debugging purposes
  }catch(Exception e){
    println("error parsing serial data: "+temp);
  }
}