您应该如何安全地创建和释放多个对象？
基本上就是这样的事情：
newOrderSource := TWebNewOrderSource.Create();
twData := TTWData.Create();
webData := TWebData.Create();
try
//do stuff
finally
newOrderSource.Free();
twData.Free();
webData.Free();
end;
在这种情况下，第二个和第三个创建命令是不安全的，因为它们与数据库一起使用。我是否应该将所有 Creates 放在 try 块中，并在调用 free 之前检查它们是否已分配？
【问题讨论】：
标签： delphi
如果您首先将 nil 分配给变量，则可以使用一个 try 块来执行此操作，例如，
newOrderSource := nil;
twData := nil;
webData := nil;
try
newOrderSource := TWebNewOrderSource.Create();
twData := TTWData.Create();
webData := TWebData.Create();
//do stuff
finally
webData.Free();
twData.Free();
newOrderSource.Free();
end;
这是因为Free() 检查Self 中的nil。
【讨论】：
newOrderSource := TWebNewOrderSource.Create();，并放弃 newOrderSource := nil;。
nil，因为 Delphi 将所有内存初始化为零，这恰好与 nil 相同。这就是为什么您不需要使用if Assigned() 来保护对 Free 的每个调用。这也是为什么你叫 Free 而不是 Destroy 的原因。
Free 不是虚拟方法，因此编译器生成一个普通函数调用，将Self 作为参数传递。这就像将nil 作为接受TObject 的过程的第一个参数传递，只是看起来有点古怪。
相信大家都知道，管理对象的标准方式是这样的：
A := TMyObject.Create;
try
A.DoSomething;
finally
A.Free;
end;
如果TMyObject.Create 中存在异常，则将调用析构函数，然后引发异常。在这种情况下，A 将不会被分配给。
当您有多个对象时，您可以重复该模式：
A := TMyObject.Create;
try
B := TMyObject.Create;
try
A.DoSomething;
B.DoSomething;
finally
B.Free;
end;
finally
A.Free;
end;
这很快就会变得一团糟，因此问题就来了。
一个标准技巧是利用Free 可以安全地在nil 对象引用上调用这一事实。
A := nil;
B := nil;
try
A := TMyObject.Create;
B := TMyObject.Create;
A.DoSomething;
B.DoSomething;
finally
B.Free;
A.Free;
end;
这确实有一个小弱点，即它对B.Free 中引发的异常没有弹性，但将其视为可以忽略的失败条件并非没有道理。析构函数不应引发异常。如果他们这样做了，那么您的系统可能已经不可挽回地损坏了。
随着更多对象的添加，上述模式可能会变得有点混乱，因此我个人使用以下辅助方法。
procedure InitialiseNil(var Obj1); overload;
procedure InitialiseNil(var Obj1, Obj2); overload;
procedure InitialiseNil(var Obj1, Obj2, Obj3); overload;
procedure FreeAndNil(var Obj1); overload;
procedure FreeAndNil(var Obj1, Obj2); overload;
procedure FreeAndNil(var Obj1, Obj2, Obj3); overload;
事实上，我的代码有更多参数的版本。为便于维护，此代码全部由简短的 Python 脚本自动生成。
这些方法以显而易见的方式实现，例如
procedure FreeAndNil(var Obj1, Obj2);
var
Temp1, Temp2: TObject;
begin
Temp1 := TObject(Obj1);
Temp2 := TObject(Obj2);
Pointer(Obj1) := nil;
Pointer(Obj2) := nil;
Temp1.Free;
Temp2.Free;
end;
这使我们可以像这样重写上面的示例：
InitialiseNil(A, B);
try
A := TMyObject.Create;
B := TMyObject.Create;
A.DoSomething;
B.DoSomething;
finally
FreeAndNil(B, A);
end;
【讨论】：