delphi 释放多个对象

Question

下面，我插入了 Ray Konopka 编写的代码（Coderage 演示文稿的一部分）。我打算使用它，但是，我不确定如何（即时）清理多个对象。 我所有的尝试都没有成功并导致内存泄漏。 任何想法表示赞赏。 谢谢，

  program stringlistDictionary;

{$APPTYPE CONSOLE}

uses
 Classes,
 SysUtils;

 type
   TPlayer = class
  public
   Name: string;
   Position: string;
   Hits: Integer;
   AtBats: Integer;
   constructor Create( Name, Position: string );
 end;


   constructor TPlayer.Create( Name, Position: string );
    begin
      inherited Create;
      Self.Name := Name;
      Self.Position := Position;
      Hits := 0;
      AtBats := 0;
    end;


    var
      Team: TStringList;
      Player, NewPlayer: TPlayer;
      I: Integer;


    function FindPlayer( const Name: string ): TPlayer;
    var
      Idx: Integer;
    begin
      Result := nil;
      if Team.Find( Name, Idx ) then
        Result := TPlayer( Team.Objects[ Idx ] );
    end;


    begin {== Main ==}

      Writeln( 'StringList Dictionary' );
      Writeln( '---------------------' );
      Writeln;

      Team := TStringList.Create;
      try
        NewPlayer := TPlayer.Create( 'Aramis Ramerez', 'Third Base' );
        NewPlayer.Hits := 120;
        NewPlayer.AtBats := 350;

        Team.AddObject( NewPlayer.Name, NewPlayer );

        NewPlayer := TPlayer.Create( 'Derrick Lee', 'First Base' );
        NewPlayer.Hits := 143;
        NewPlayer.AtBats := 329;

        Team.AddObject( NewPlayer.Name, NewPlayer );

        NewPlayer := TPlayer.Create( 'Ryan Theriot', 'Short Stop' );
        NewPlayer.Hits := 87;
        NewPlayer.AtBats := 203;

        Team.AddObject( NewPlayer.Name, NewPlayer );

        Player := FindPlayer( 'Derrick Lee' );
        if Player <> nil then
          Writeln( 'Player Found: ', Player.Name, ', ', Player.Position )
        else
          Writeln( 'Player not found.' );
        Writeln;

        Writeln( 'Active Roster' );
        Writeln( '-------------' );

        for I := 0 to Team.Count - 1 do
          Writeln( TPlayer( Team.Objects[ I ] ).Name, #9,
                   TPlayer( Team.Objects[ I ] ).Position );

        Readln;

      finally
        //!! Need to free the players.
        Team.Free;
      end;

    end.

Answer 1

在 Delphi 2009 中，TStringList 构造函数有一个可选的布尔参数“OwnsObjects”。如果将其设置为 true，则会自动释放对象。

您还可以执行以下操作：

for i := Team.Count-1 downto 0 do begin
  Team.Objects.Free;
end;
Team.Free;

顺便说一句，不鼓励使用公共字段。您最好使用属性，这样您就可以控制对字段的访问权限。并且您可以添加 setter 函数来验证输入。

type
  TPlayer = class
  private
    FName     : string;
    FPosition : string;
    FHits     : Integer;
    FAtBats   : Integer;
  public
    constructor Create(const AName, APosition: string );

    property Name: string read FName;
    property Position: string read FPosition;
    property Hits: Integer read FHits write FHits;
    property AtBats: Integer read FAtBats write FAtBats;
 end;

Answer 2

有点明显，但仍然 - 您不必每次要清除 TStringList 对象时都编写“for ... Free”代码。你可以把它放到一个全局函数中。

procedure FreeObjects(sl: TStringList);
var
  i: integer;
begin
  for i := 0 to sl.Count - 1 do 
    sl.Objects[i].Free;
end;

FreeObjects(Team);

或者你可以把它放到一个 TStringList 助手中。

TStringListHelper = class helper for TStringList
public
  procedure FreeObjects;
end;

procedure TStringListHelper.FreeObjects;
var
  i: integer;
begin
  for i := 0 to Count - 1 do 
    Objects[i].Free;
end;

Team.FreeObjects;

Answer 3

只是对gamecat回答的澄清：我不知道delphi 2009，但通常 Objects 属性需要一个索引，而你并不真的需要一个反向循环，所以：

for i := 0 to Team.Count-1 do
  Team.Objects[i].Free;
Team.Free;

或：

while Team.Count > 0 do
begin
  Team.Objects[0].Free;
  Team.Delete(0);
end;
Team.Free;

Answer 4

使用 D7，我可以将 TStingList 子类化