Delphi中的结果值逻辑？

Question

我正在编写这个函数，其中 如果一个字符串仅相差一个字符，则返回不同的字符位置，如果它们是正确的，则应该返回 -1 和 -10大小写相差超过 1 个字符。

仅作为示例，'010' 和 '110' 或 '100' 和 '110' 效果很好，分别返回 0 和 1...

但是，当我尝试使用'100' 和'101' 或'110' 和'111' 我得到-1 的结果，而它应该是2！我已经完成了桌面测试，但我不能只看到错误。

function combine (m1, m2 : string) : integer;
var
dash : integer;
distinct : integer;
i : integer;

begin
distinct := 0;
dash := -1;

for i := 0 to Length(m1)-1 do
begin
    if m1[i] <> m2[i] then
    begin
      distinct := distinct+1;
      dash := i;
      if distinct > 1 then
        begin
          result:= -10;
          exit;
        end;
    end;
end;
result := dash;
end;

我总是得到相同长度的字符串， 我做错了什么？

Answer 1

主要问题是 Delphi 字符串是从 1 开始的。您的循环需要从1 运行到Length(m1)。

如果您在编译器选项中启用了范围检查，那么编译器会在运行时引发错误，从而导致您出错。我不能强调你应该启用范围检查。它会导致编译器在你的代码中发现错误。

另请注意，这意味着返回的值也将从 1 开始。因此'100', '101' 的输入将给出结果3，因为这是第一个差异的索引。

您还应该检查m1 和m2 的长度是否相同。如果不引发异常。

另一个提示。将变量加 1 的惯用方法如下：

inc(distinct);

如果你想增加一个不同的值，写：

inc(distinct, n);

所以，我会这样写函数：

function combine(const m1, m2: string): integer;
var
  i: integer;
  dash: integer;
  distinct: integer;
begin
  if Length(m1)<>Length(m2) then begin
    raise EAssertionFailed.Create('m1 and m2 must be the same length');
  end;

  distinct := 0;
  dash := -1;

  for i := 1 to Length(m1) do
  begin
    if m1[i] <> m2[i] then
    begin
      inc(distinct);
      dash := i;
      if distinct > 1 then
      begin
        result := -10;
        exit;
      end;
    end;
  end;
  result := dash;
end;