Excel - 源单元格为计数的标准偏差答案

【问题标题】：Excel - standard deviation where source cells are a countExcel - 源单元格为计数的标准偏差
【发布时间】：2021-07-27 00:27:32
【问题描述】：

我有一些看起来像这样的数据

Condition 1	Condition 2	Condition 3	Condition 4	Condition 5
0	0	0	70	0
0	50	10	0	0
120	0	0	5	5

每个单元格中的值是给定条件下资产的米数。或者换句话说，计数为“4”的米数。我如何计算这个的标准偏差？显然，第一行的 std.dev 将为“0”，第二行更高，第三行相当低。类似于 REPT 的东西，但在公式中重复一个值 x 次？我考虑了一个辅助列，但总米数使这不切实际。

【问题讨论】：

你能不能让它更具体一些，好吗？我不清楚你需要什么。 ⬤ 第一行是否意味着有 70 次相同的值（在您的示例中为“4”）并且该系列中没有其他值？
你有得到计数最初来自的数据吗？
为了澄清，现场工作人员评估资产并按米记录状况。例如在第 1 行，我们有 70m 的资产，所有这些都是条件 4。在第 2 行，我们有 60m 的资产，其中 50m 是条件 2，10m 是条件 3。在第 3 行 - 130m 资产，120m是'1'，5m 是'4'，5m 是'5'。我已经发布了一个我认为已经解决的答案。

【解决方案1】：

我不是数学专家，但我可以向您展示如何使用 Excel 365 根据显示的标准“制作一系列数字”。

假设您的数据在B2:F4 范围内，如下所示。在单元格G2中，输入以下公式并向下拖动：

=STDEV.P(--FILTERXML("<t><s>"&TEXTJOIN("</s><s>",1,REPT($B$1:$F$1&"</s><s>",$B2:$F2))&"</s></t>","//s[number()=.]"))

上面将使用 STDEV.P 函数计算标准偏差，但我不确定这是否是正确使用的函数，因为原始 STDEV 函数。

无论如何，公式的以下部分能够根据需要返回一个数字范围：

=--FILTERXML("<t><s>"&TEXTJOIN("</s><s>",1,REPT($B$1:$F$1&"</s><s>",$B2:$F2))&"</s></t>","//s[number()=.]")

您可以查看这个question和JvdV的回答，了解FILTERXML函数的使用。

【讨论】：

【解决方案2】：

另一种方法是使用替代 SD 公式

这会给你

=SQRT((SUM(A2:E2*COLUMN(A2:E2)^2)-SUM(A2:E2*COLUMN(A2:E2))^2/SUM(A2:E2))/SUM(A2:E2))

为总体标准差。

我认为使用 Let 的 Excel 365 版本更具可读性：

=LET(x,COLUMN(A2:E2),
mpy,A2:E2,
n,SUM(mpy),
sumxsq,SUM(mpy*x^2),
sumsqx,SUM(mpy*x)^2,
numerator,sumxsq-sumsqx/n,
SQRT(numerator/n)
)

不太明显，你可以从原始公式中得到它

=SQRT(SUM(A2:E2*(COLUMN(A2:E2)-SUM(A2:E2*COLUMN(A2:E2))/SUM(A2:E2))^2/SUM(A2:E2)))

同样，在 Excel 365 中，您可以这样写：

=LET(x,COLUMN(A2:E2),
mpy,A2:E2,
n,SUM(mpy),
xbar,SUM(mpy*x/n),
numerator,SUM(mpy*(x-xbar)^2),
SQRT(numerator/n)
)

将分母改为

(SUM(A2:E2)-1)

为样本标准差。

【讨论】：

【解决方案3】：

我最终弄明白了。我添加了一个计算平均值的列。（说 F 列）然后我有一个这样的公式

=SQRT(SUM(A2*POWER((1-F2),2),B2*POWER((2-F2),2),C2*POWER((3-F2),2),D2*POWER((4-F2),2),E2*POWER((5-F2),2))/SUM(A2:E2))

基本上这是计算每个条件值的平均值的方差，乘以特定条件下资产的值数（例如米数），然后进行正常的其他标准偏差计算（总和，除以总数, 正方形)。

【讨论】：