如何在 Excel 中使用多个切片器链接表格和数据透视表？答案

【问题标题】：How to link a Table and a Pivot Table using more than one slicer in Excel?如何在 Excel 中使用多个切片器链接表格和数据透视表？
【发布时间】：2018-08-03 19:52:52
【问题描述】：

我在使用切片器链接表和数据透视表时遇到了同样的问题。 [jeffreyweir]提供的答案很完美！但就我而言，我需要使用 3 个或更多不同切片器的解决方案。

可以通过以下链接找到初始解决方案：How to link a Table and a Pivot Table using Slicers in Excel?

提前很多 tks，我希望我以正确的方式遵守这个奇妙网站的规则！ ;-)

【问题讨论】：

您想要多个切片器，因为您想过滤多个列/字段？
没错！例如。用户可能希望筛选一个区域，然后筛选一个（或多个）负责该地区销售的经理

标签： pivot-table slicers

【解决方案1】：

好的，所以我修改了代码，使其只需要数据透视表切片器，并且它使用这些切片器设置来直接过滤表。请注意，您需要更改代码中的以下几行以匹配您的表和数据透视表的名称：

Const sPivot As String = "PivotTable1" '<= Change name as appropriate

Const sTable As String = "Table1" '<= Change name as appropriate

此代码必须粘贴到属于工作表的工作表模块，相关的表/数据透视表是：

Option Explicit

Private Sub Worksheet_PivotTableUpdate(ByVal Target As PivotTable)
Dim sLastUndoStackItem As String
Dim sc          As SlicerCache
Dim si          As SlicerItem
Dim vItems      As Variant
Dim i           As Long
Dim lo          As ListObject
Dim lc          As ListColumn
Dim sTest       As String

Const sPivot As String = "PivotTable1" '<= Change name as appropriate
Const sTable As String = "Table1" '<= Change name as appropriate

If Target.Name = sPivot Then
    On Error Resume Next 'in case the undo stack has been wiped or doesn't exist
    sLastUndoStackItem = Application.CommandBars(14).FindControl(ID:=128).List(1) 'Standard Commandbar, undo stack
    'The above line doesn't seem to work in my version of O365 so we'll use the English language backup
    If sLastUndoStackItem = "" Then sLastUndoStackItem = Application.CommandBars("Standard").Controls("&Undo").List(1)
    On Error GoTo 0

    If sLastUndoStackItem = "Filter" Or sLastUndoStackItem = "Slicer Operation" Then

        Set lo = Range(sTable).ListObject

        For Each sc In ActiveWorkbook.SlicerCaches
            On Error Resume Next
            sTest = sc.PivotTables(1).Name
            On Error GoTo 0
            If sTest = sPivot Then
                Set lc = lo.ListColumns(sc.SourceName)
                If sc.FilterCleared Then
                    lo.Range.AutoFilter Field:=lc.Index
                Else
                    ReDim vItems(1 To 1)
                    For Each si In sc.SlicerItems
                        If si.Selected Then
                            i = i + 1
                            ReDim Preserve vItems(1 To i)
                            vItems(i) = si.Name
                        End If
                    Next si

                    lo.Range.AutoFilter Field:=lc.Index, Criteria1:=vItems, Operator:=xlFilterValues
                    ReDim vItems(1 To 1)
                End If
            End If
        Next sc
    End If
End If


End Sub

它正在发挥作用：

【讨论】：

Jeff 很抱歉让我这么久才给您反馈。但你是个天才！！
酷。请通过单击答案旁边的复选标记将答案从灰色切换为已填充，将答案标记为已接受。
很多很多的tks！完全同意你的“上帝赐予我 VBA 技能，让我无法轻易改变的事情自动化；我可以充分利用内置功能的知识；以及了解差异的智慧”：-D

【解决方案2】：

对于那些在数据表与数据透视表不同的工作表上的人，只需更改

Set lo = Range(sTable).ListObject

到

Set lo = Sheets("table_sheet_name").Range(sTable).ListObject

并将代码存储在数据透视表工作表模块中。

【讨论】：