为什么将 ADODB.Stream 与 A​​SCII 字符集特殊字符作为 ä 转换为 a？

Question

我在尝试将 vb6 中某些变量的内容输出到文本文件时遇到问题。问题是，当扩展 ASCII 中的特殊字符显示为 ä、ü、á 时，它会在输出中转换为匹配的基本 ASCII 字符，如 a、u、a。

我尝试像 UTF-8 一样导出它，然后正确显示字符，但我需要输出为 ASCII。此外，对我来说，文件名通常可以包含这个字符（ä、ü、á...）而对我来说看起来很奇怪。

这可能是因为“ASCII”字符集只是基本字符集而不是扩展字符集吗？也许是因为 Windows 中配置的 CodePages？我尝试了其中几个（德语、英语），结果相同。

这是我正在使用的代码：

Set fileStream = New ADODB.Stream
If Not fileStream Is Nothing Then
    inputString = textPreAppend + inputString
    fileStream.charSet = "ASCII"
    fileStream.Open
    fileStream.WriteText inputString
    fileStream.Flush
    fileStream.SaveToFile fileName, adSaveCreateOverWrite
    fileStream.Flush
    fileStream.Close
End If
Set fileStream = Nothing

提前致谢！

Answer 1

PRB: Charset Property of ADO Stream Object May Require Microsoft Internet Explorer Upgrade 和 Charset Property (ADO) 都表明 ADO CharSet 值是列在HKEY_CLASSES_ROOT\MIME\Database\Charset 下的值，但这显然不是全部。

例如，“ascii”和“us-ascii”这两个值都列为“iso-8859-1”的别名，但是在我的语言环境设置为美国英语的情况下运行它们就像一个 7 位 ASCII MIME 类型。他们几乎必须这样做，因为无论如何都没有为请求 7 位 ASCII 编码提供任何其他功能。

这会产生您想要的结果：

Option Explicit

Private Sub Main()
    Dim fileStream As ADODB.Stream
    Dim inputString As String
    Const FileName As String = "outputfile.txt"

    Set fileStream = New ADODB.Stream
    inputString = "The thing is that when a special character" & vbNewLine _
                & "from extended ASCII appears as ä, ü, á it" & vbNewLine _
                & "is transformed in the output to the matching" & vbNewLine _
                & "basic ASCII char like a, u, a." & vbNewLine
    With fileStream
        .Type = adTypeText
        .Charset = "iso-8859-1"
        .Open
        .WriteText inputString
        .SaveToFile FileName, adSaveCreateOverWrite
        .Close
    End With
End Sub

输出：

The thing is that when a special character
from extended ASCII appears as ä, ü, á it
is transformed in the output to the matching
basic ASCII char like a, u, a.

我们必须假设要求“ascii”（这些值都是小写的，但显然不区分大小写）意味着 7 位 ASCII，可能是本地化的。

除非您想要 UTF-8，否则使用 UTF-8 是个坏主意。虽然许多 *nix 系统假装没有区别，但 Stream 会写入 BOM，当然那些扩展（非 ASCII）字符是多字节编码的。

Answer 2

为什么你不能做如下的事情？这对我来说没问题：

    Dim FileNo As Integer
    Dim strFile As String

    strFile = "C:\Test.txt"
    FileNo = FreeFile

    Dim strVariable As String
    strVariable = "some text with extended chars in: ÙÑáêôü"

    Open strFile For Append As #FileNo

    Print #FileNo, strVariable

    Close #FileNo