在 a 和 b 之间生成“n”个随机数以在 m 行中达到所需的平均值

Question

假设在有 200 行的列 Z 中，是我的最佳平均值。

现在我想要一个宏，它可以在 a 和 b 之间生成 n 随机整数 (n <= 20)，这样使用最佳平均值生成的数字的平均值之间的差异就在 (-0.15,+0.15) 中。

例子：

Z1:optimal average1=5.5
Z2:optimal average2=5.3

Z200:optimal average200=6.3
n=8
a=1; b=10
numbers of generated:
A1:H1)5-9-4-3-7-4-9-3
A2:H2)10-7-3-2-5-4-3-9
.
.
.
A200:H200)4-8-9-6-6-6-10-2

Answer 1

这里是一个命中或失败的方法（这通常是获得随机数的唯一可行方法，这些随机数以无偏的方式满足额外的约束）：

Function RandIntVect(n As Long, a As Long, b As Long, mean As Double, tol As Double, Optional maxTries As Long = 1000) As Variant
    'Uses a hit-or-miss approach to generate a vector of n random ints in a,b inclusive whose mean is
    'within the tolerance tol of the given target mean
    'The function raises an error if maxTries misses occur without a hit

    Dim sum As Long, i As Long, j As Long
    Dim lowTarget As Double, highTarget As Double 'targets for *sums*
    Dim vect As Variant

    lowTarget = n * (mean - tol)
    highTarget = n * (mean + tol)

    For i = 1 To maxTries
        ReDim vect(1 To n)
        sum = 0
        j = 0
        Do While j < n And sum + a * (n - j) <= highTarget And sum + b * (n - j) >= lowTarget
            j = j + 1
            vect(j) = Application.WorksheetFunction.RandBetween(a, b)
            sum = sum + vect(j)
        Loop
        If j = n And lowTarget <= sum And sum <= highTarget Then
            'Debug.Print i 'uncomment this line to see how many tries required
            RandIntVect = vect
            Exit Function
        End If
    Next i
    'error if we get to here
    RandIntVect = CVErr(xlErrValue)
End Function

这可以用作worksheet array formula。目标均值在I 列中，在A2:H2 中我输入了=RandIntVect(8,1,10,I2,0.15)（使用 ctrl+shift+enter 作为数组公式），然后向下复制：

请注意，数组公式是易变的，因此每次工作表出现时都会重新计算这些数字。您可以使用 VBA 中的函数将数字直接放在范围内，而不是将函数用作工作表公式。比如：

Sub test()
    Dim i As Long
    For i = 1 To 3
        Range(Cells(i + 1, 1), Cells(i + 1, 8)).Value = RandIntVect(8, 1, 10, Cells(i + 1, 9).Value, 0.15)
    Next i
End Sub

Answer 2

enter image description here

两种均值之差不在范围（0.15+，0.15-）内