为什么 CM_CONTROLLISTCHANGE 对间接父控件执行？

Question

我注意到，如果我有一个主容器/父级 (MainPanel)，向它添加一个子面板 (ChildPanel)，将在 MainPanel (TWinControl.InsertControl()) 上执行 CM_CONTROLLISTCHANGE，这很好.

但是，如果我将子控件 (ChildButton) 插入到 ChildPanel，则会为主 MainPanel 再次触发 CM_CONTROLLISTCHANGE！

这是为什么呢？将ChildButton 插入ChildPanel 时，我希望CM_CONTROLLISTCHANGE 只为ChildPanel 触发。

MCVE

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  ExtCtrls, StdCtrls;

type
  TMainPanel = class(ExtCtrls.TCustomPanel)
  private
    procedure CMControlListChange(var Message: TCMControlListChange); message CM_CONTROLLISTCHANGE;
  end;

  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
  private
  public
    MainPanel: TMainPanel;
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

procedure TMainPanel.CMControlListChange(var Message: TCMControlListChange);
begin
  if Message.Inserting then
  begin
    Form1.Memo1.Lines.Add('TMainPanel.CMControlListChange: Inserting ' + Message.Control.ClassName);
    // Parent is always nil
    if Message.Control.Parent = nil then Form1.Memo1.Lines.Add('*** Parent=nil');
  end;
  inherited;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  ChildPanel: TPanel;
  ChildButton: TButton;
begin
  FreeAndNil(MainPanel);

  MainPanel := TMainPanel.Create(Self);
  MainPanel.SetBounds(0, 0, 200, 200);
  MainPanel.Parent := Self;

  ChildPanel := TPanel.Create(Self);
  ChildPanel.Parent := MainPanel;

  ChildButton := TButton.Create(Self);
  ChildButton.Parent := ChildPanel; // Why do I get CM_CONTROLLISTCHANGE in "MainPanel"?
end;

end.

DFM

object Form1: TForm1
  Left = 192
  Top = 114
  Width = 685
  Height = 275
  Caption = 'Form1'
  Color = clBtnFace
  Font.Charset = DEFAULT_CHARSET
  Font.Color = clWindowText
  Font.Height = -11
  Font.Name = 'MS Shell Dlg 2'
  Font.Style = []
  OldCreateOrder = False
  PixelsPerInch = 96
  TextHeight = 13
  object Button1: TButton
    Left = 592
    Top = 8
    Width = 75
    Height = 25
    Caption = 'Button1'
    TabOrder = 0
    OnClick = Button1Click
  end
  object Memo1: TMemo
    Left = 456
    Top = 40
    Width = 209
    Height = 193
    TabOrder = 1
  end
end

P.S：我不知道这是否重要，但我在 Delphi 5 上。

Answer 1

使用调试器实际上很容易回答这个问题。你自己也可以很容易地做到这一点。启用调试 DCU 并在 TMainPanel.CMControlListChange 中的 if 语句内设置断点。

第一次触发此断点是在插入子面板时。正如您所期望的那样，正在添加主面板的直接子面板，即子面板。断点触发的第二次是兴趣点。这就是添加子面板的子项的时候。

当这个断点触发时，调用栈是这样的：

TMainPanel.CMControlListChange((45100, $22420EC, True, 0)) TControl.WndProc((45100, 35922156, 1, 0, 8428, 548, 1, 0, 0, 0)) TWinControl.WndProc((45100, 35922156, 1, 0, 8428, 548, 1, 0, 0, 0)) TWinControl.CMControlListChange((45100, 35922156, 1, 0, 8428, 548, 1, 0, 0, 0)) TControl.WndProc((45100, 35922156, 1, 0, 8428, 548, 1, 0, 0, 0)) TWinControl.WndProc((45100, 35922156, 1, 0, 8428, 548, 1, 0, 0, 0)) TControl.Perform(45100,35922156,1) TWinControl.InsertControl($22420EC) TControl.SetParent($2243DD4) TForm1.Button1Click(???)

此时我们可以通过双击每个项目来简单地检查调用堆栈。我将从TForm1.Button1Click 开始，这证实了我们确实在回复ChildButton.Parent := ChildPanel。您的作品名列前茅。

两个项目我们来到TWinControl.InsertControl，当我们双击这个项目时，我们发现：

Perform(CM_CONTROLLISTCHANGE, Integer(AControl), Integer(True));

这里，AControl 是按钮，Self 是子面板。让我们继续向上直到TWinControl.CMControlListChange。现在，这是处理该消息的地方，我们仍然有 Self 作为子面板。这个函数的主体是：

procedure TWinControl.CMControlListChange(var Message: TMessage);
begin
  if FParent <> nil then FParent.WindowProc(Message);
end;

这就是谜题的答案。 VCL 将消息向上传播到父链。然后，该调用将转到调用堆栈的顶部，TMainPanel.CMControlListChange，其中Self 现在是主面板，在对TWinControl.CMControlListChange 的调用中是FParent。

我知道我可以简单地指向TWinControl.CMControlListChange，这样就可以直接回答这个问题。但我真的想说一点，这样的问题很容易通过相对简单的调试来解决。

请注意，我已经调试了这个 Delphi 6，它是我所拥有的最接近 Delphi 5 的现成版本，但这里概述的原则和答案在所有版本中仍然有效。