将 <T> 类型的值转换为 Variant，可以吗？

Question

这是一个 sn-p，显示了我想要实现的目标：

type
  TMyObject<T> = class (TObject)
    function GetVarType(Value: T): TVarType;
  end;


function TMyObject<T>.GetVarType(Value: T): TVarType;
var
  TmpValue: Variant;
begin
  TmpValue := Variant(Value); //Invalid typecast
  Result := VarType(TmpValue);
end;

我知道上面带有类型转换的方法很幼稚，但我希望你明白这一点。我想用一些转换机制来代替它。

TMyObject 将始终是简单类型，例如 Integer、String、Single、Double。

这种转换的目的是函数 VarType 为我可以存储在其他地方的每个简单类型提供整数常量。

我想知道这种转换是否可行？

感谢您的宝贵时间。

Answer 1

使用增强的 RTTI（2010 和更新版本）在 Delphis 中可以轻松解决。太糟糕了，你仅限于 2009 年 :(

function TMyObject<T>.GetVarType(Value: T): TVarType;
begin
  Result := VarType(TValue.From<T>(Value).AsVariant);
end;

这仅适用于简单类型，但这是问题中指定的约束。

Answer 2

您可以使用 RTTI 获取此信息，只需检查 TTypeInfo.Kind 属性的值：

查看此示例代码

{$APPTYPE CONSOLE}

uses
  TypInfo,
  Variants,
  Generics.Collections,
  SysUtils;

type
  TMyObject<T> = class (TObject)
    function GetVarType(Value: T): TVarType;
  end;


function TMyObject<T>.GetVarType(Value: T): TVarType;
begin
  Case PTypeInfo(TypeInfo(T))^.Kind of
    tkInteger : Result:=varInteger;
    tkFloat   : Result:=varDouble;
    tkString  : Result:=varString;
    tkUString : Result:=varUString;
    //add more types here
  End;
end;

Var
  LObj : TMyObject<Integer>;
begin
  try
     Writeln(VarTypeAsText(TMyObject<Integer>.Create.GetVarType(5)));
     Writeln(VarTypeAsText(TMyObject<String>.Create.GetVarType('Test')));
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  Readln;
end.

这将返回

Integer
UnicodeString

Answer 3

我看不出用泛型怎么可能做到这一点。编译器需要知道T 类型的实例可以分配给任何可能的T 的Variant。您无法告诉编译器这是可能的。

如果这是 C++ 中的模板，那么这将是微不足道的。

Answer 4

感谢大家的回答：

正如@RRUZ 所表明的那样（我的意思不是严格分配，而是提取数据类型）。我在等待任何答案的同时独自工作，并找到了更通用的解决方案。

所以我把它放在这里：

type
  TMyObject<T> = class (TObject)
    function GetVarType(Value: T): TVarType;
  end;


function TMyObject<T>.GetVarType(Value: T): TVarType;
begin
  Result := GetTypeData(TypeInfo(T)).varType;
end;

再次感谢！