DBGrid / DataSet 无法按照 CommandText 中设置的 sql 语句进行排序

Question

我在我正在使用的DataSet 的CommandText 属性中使用以下内容：

SELECT *
FROM table_name
ORDER BY FIELD(priority, 'urgent', 'normal'),
         FIELD(state, 'wait', 'executed', 'done')

它应该对我在连接到此DataSet 的DBGrid 中显示的数据进行排序，如下所示：

1. 1. priority 列中包含 urgent 的行应启动 DBGrid 列表。
   2. 那么列表应该继续在priority 列中标记为normal 的列表，
2. 1. 紧随其后的是state 列中标记为wait 的那些，
   2. 后面是state 列中标记为executed 的那些，
   3. 最后，列表以state 列中标记为done 的列表结束。

但它没有，实际上它确实有点，但它实际上是倒退的。 这是我制作的快速视频，向您展示正在发生的事情，也许您可​​以通过这种方式获得更清晰的视图：

Video of what's happening

我猜这是因为我正在使用的 ID column 或 Date column 但如果是这样，我不知道如何以及为什么。

这就是这两列的外观/设置方式：

• ID 列设置为 Primary 和 Unique 和 Auto_Increment - 就是这样，没有索引或任何其他选项 如果不是这 2 列的问题，那么可能是 DBGrid？

我正在使用 RAD Studio 10 Seattle、dbExpress 组件（TSimpleDataSet 等）和 MySQL db

关于如何解决这个问题的任何想法？谢谢！

Answer 1

按照自己的方式去做，让生活变得不必要地困难。

没有必要让服务器进行排序（通过使用 ORDER BY 子句，并且可以说在客户端而不是在服务器上进行排序更好，因为客户端通常有空闲的计算能力而服务器可能不会。

所以，这是我建议的解决方法：

1. 从您的 SQL 中删除 ORDER BY，然后执行 SELECT * [...]。

2. 将您的 SimpleDataSet 替换为 ClientDataSet 并在其上定义持久 TField。进行此更改的原因是为了能够创建两个 fkInternalCalc 类型的持久字段。

3. 在 Object Inspector 的 TFields 编辑器中，定义两个 fkInternalCalc 字段，称为 PriorityCode 和 StateCode。

4. 将数据集的 IndexFieldNames 属性设置为“PriorityCode;StateCode”。

5. 在数据集的 OnCalcFields 事件中，计算 PriorityCode 和 StateCode 的值，这将给出您希望数据行具有的排序顺序。

类似：

procedure TForm1.ClientDataSet1CalcFields(DataSet: TDataSet);
var
  S : String;
  PriorityCodeField,
  StateCodeField : TField;
  iValue : Integer;
begin
  PriorityCodeField := ClientDataset1.FieldByName('PriorityCode');
  StateCodeField := ClientDataset1.FieldByName('StateCode');
  S := ClientDataset1.FieldByName('Priority').AsString;
  if S = 'urgent' then
    iValue := 1
  else
    if S = 'normal' then
      iValue := 2
    else
      iValue := 999;
  PriorityCodeField.AsInteger := iValue;

  S := ClientDataset1.FieldByName('State').AsString;
  if S = 'wait' then
    iValue := 1
  else
    if S = 'executed' then
      iValue := 2
    else
      if S = 'done' then
        iValue := 3
      else
        iValue := 999;
  StateCodeField.AsInteger := iValue;

end;

实际上，如果您避免使用FieldByName 并仅使用 OI 的 Tfields 编辑器创建的字段，会更好（更快，更少开销），因为这些字段会自动绑定到 ClientDataSet 的数据字段。已打开。

顺便说一句，记住虽然 TClientDataSet 不能在 TFields 编辑器中定义为 Calculated 的字段上排序，但它可以在 InternalCalc 字段上排序。