如何检测对 TListView 中 CheckBox 的点击答案

【问题标题】：How to detect a click on the CheckBox in the TListView如何检测对 TListView 中 CheckBox 的点击
【发布时间】：2017-08-15 12:33:16
【问题描述】：

所以基本上当用户点击复选框时，我想将该项目添加到我的列表中，我尝试使用 OnChange 事件，但这对我不起作用，因为即使未点击复选框，它也会被触发。

我的代码简单明了

procedure LvUserChange(Sender: TObject; Item: TListItem;Change: TItemChange);
 var
 objUser : TUsers;
begin
   if not assigned(objListOfChangedUsers) then
   objListOfChangedUsers := TObjectList.Create;

   objUser := Item.Data;
   objListOfChangedUsers.Add(objUser);
end;

我希望仅在单击 ListView 中的复选框时触发此代码

【问题讨论】：

真的吗？为我工作。向我们展示您的代码并解释发生了什么不良行为。
不想要的行为是 Onchange 事件会触发，即使没有像我在问题中所说的那样单击复选框，还有其他我可以使用的事件或方法吗？
您似乎使用的是 OnChange 事件而不是 OnClick 事件。无论出于何种原因，每次更改组件时都会触发 OnChange 事件。
D2007 中是否存在OnItemChecked 事件？
@Dsm 你是说我应该使用 OnClick 事件吗？即使我没有点击复选框，这不会触发吗？

标签： delphi delphi-2007 tlistview

【解决方案1】：

在 Delphi 2009 及更高版本中，您可以使用 TListView.OnItemChecked 事件来检测复选框单击。 Delphi 2007 没有这样的事件，在这种情况下，您需要在自己的代码中手动检测通知。我将使用一个 interposer 类进行演示，但还有其他方法可以做到这一点。

uses
  ..., CommCtrl, ComCtrls, ...;

type
  TListView = class(ComCtrls.TListView)
  protected
    procedure CNNotify(var Message: TWMNotifyLV); message CN_NOTIFY;
  end;

....

procedure TListView.CNNotify(var Message: TWMNotifyLV);
begin
  inherited;
  if Message.NMHdr.code = LVN_ITEMCHANGED then
  begin
    if (Message.NMListView.uChanged = LVIF_STATE) and
       ( ((Message.NMListView.uOldState and LVIS_STATEIMAGEMASK) shr 12)
         <> ((Message.NMListView.uNewState and LVIS_STATEIMAGEMASK) shr 12)) then
    begin
      // changing check box state will land you here
    end;
  end;
end;

【讨论】：

这是正确的解决方案，以及 TListView 如何在 Delphi 2009+ 中实现 OnItemChecked 事件。但是，请注意复选框是作为状态图像实现的，OnChanging 和 OnChange 事件会在项目的复选框状态（正在）更改时用Change=ctState 触发，并且TListItem 确实有Checked 2007 年的财产。
@David，因为这有点像黑客，最好把它放在一个单独的单元中？
我就是这样做的。我会创建一个派生类，它与现代 Delphi 出现相同的事件。但这完全取决于您如何组织代码。

【解决方案2】：

由于 OnItemChecked 不存在，因此您无法仅在选中项目时触发事件，但您可以像这样过滤事件

procedure LvUserChange(Sender: TObject; Item: TListItem;Change: TItemChange);
 var
 objUser : TUsers;
begin
   if Change = ctState then
   begin
     if Item.Checked then
     begin
       if not assigned(objListOfChangedUsers) then
       objListOfChangedUsers := TObjectList.Create;

       objUser := Item.Data;
       objListOfChangedUsers.Add(objUser);
     end
     else
     begin
       // just in case there are any actions when unchecking
     end;
   end;
end;

我没有 Delphi 2007，但检查了文档，它应该可以工作。

【讨论】：

我可以确认这不起作用，因为即使未单击复选框而是将焦点放在“选中”项目上，事件也会触发，然后所有条件都变为真并最终添加列表中的项目