TFileStream 将数据写入下一行

Question

我正在操作 TFileStream，我想将数据写入下一行。

以下代码重写了前一个...

我可以做些什么来包装并让它在那里写下新的一行？

function TParserSkyecc.GenerateHTMLFile(pathHtml,out1,out2,out3,out4,out5 : String) : Boolean;
var FS: TFileStream;
begin
  FS := TFileStream.Create(pathHtml+'\filename.txt',fmCreate or fmOpenWrite or fmShareDenyNone);
  try
  FS.Seek(0,soFromBeginning);
    FS.WriteBuffer(Pointer(AnsiString(out1))^,Length(out1));
    FS.WriteBuffer(Pointer(AnsiString(out2))^,Length(out2));
    FS.WriteBuffer(Pointer(AnsiString(out3))^,Length(out3));
    FS.WriteBuffer(Pointer(AnsiString(out4))^,Length(out4));
    FS.WriteBuffer(Pointer(AnsiString(out5))^,Length(out5));
  finally
    FS.Free;
  end;
end;

Answer 1

更简单的编写方法是直接使用TStreamWriter 而不是TFileStream。 TStreamWriter 在其构造函数中采用 TEncoding，并具有 WriteLine() 方法。例如：

function TParserSkyecc.GenerateHTMLFile(pathHtml,out1,out2,out3,out4,out5 : String) : Boolean;
var
  Filename: string;
  Writer: TStreamWriter;
begin
  Result := False;
  try
    Filename := IncludeTrailingPathDelimiter(pathHtml) + 'filename.txt'; // or: TPath.Combine(pathHtml, 'filename.txt')
    Writer := TStreamWiter.Create(Filename, False, TEncoding.ANSI);
    try
      Writer.WriteLine(out1);
      Writer.WriteLine(out2);
      Writer.WriteLine(out3);
      Writer.WriteLine(out4);
      Writer.WriteLine(out5);
      Writer.Flush;
      Result := True;
    finally
      Writer.Free;
    end;
  except
  end;
end;

或者，您可以改用TStringList：

function TParserSkyecc.GenerateHTMLFile(pathHtml,out1,out2,out3,out4,out5 : String) : Boolean;
var
  Filename: string;
  SL: TStringList;
begin
  Result := False;
  try
    Filename := IncludeTrailingPathDelimiter(pathHtml) + 'filename.txt'; // or: TPath.Combine(pathHtml, 'filename.txt')
    SL := TStringList.Create;
    try
      SL.Add(out1);
      SL.Add(out2);
      SL.Add(out3);
      SL.Add(out4);
      SL.Add(out5);
      SL.SaveToFile(Filename, TEncoding.ANSI);
      Result := True;
    finally
      SL.Free;
    end;
  except
  end;
end;

Answer 2

uses System.Classes, System.SysUtils, System.IOUtils;

VAR pathHtml : STRING;

PROCEDURE Test(CONST TXT : STRING);
  VAR
    FS  : TStream;
    N   : TFileName;
    B   : TBytes;

  BEGIN
    N:=TPath.Combine(pathHtml,'filename.txt');
    IF NOT TFile.Exists(N) THEN
      FS:=TFileStream.Create(N,fmCreate OR fmShareDenyNone)
    ELSE BEGIN
      FS:=TFileStream.Create(N,fmOpenWrite OR fmShareDenyNone);
      FS.Position:=FS.Size
    END;
    TRY
      B:=TEncoding.ANSI.GetBytes(TXT);
      FS.WriteBuffer(B,LENGTH(B))
    FINALLY
      FS.Free
    END
  END;

对实施的评论：

1. 使用 TPath.Combine 组合目录和文件名
2. 使用 TEncoding.ANSI.GetBytes 将 UNICODE 字符串转换为 ANSI。您在上面使用的版本是错误的，因为 UNICODE 字符串的 AnsiString 等效项的长度可能与 UNICODE 字符串 f.ex 的长度不同。当您的国家字符在 UNICODE 中作为一对编码但在 AnsiString 中作为单个字节编码时，您可能最终（尝试）写入比 AnsiString 转换产生的字节更多的字节。
3. 小心使用 AnsiString（和 TEncoding.ANSI），因为它取决于运行程序的计算机的语言/区域设置。

如果汤姆在 cmets 中所说的话： Asker 希望将字符串放在文件中的不同行上。 是真的，那么很简单。只需替换行

FS.WriteBuffer(Pointer(AnsiString(out1))^,Length(out1));
FS.WriteBuffer(Pointer(AnsiString(out2))^,Length(out2));
FS.WriteBuffer(Pointer(AnsiString(out3))^,Length(out3));
FS.WriteBuffer(Pointer(AnsiString(out4))^,Length(out4));
FS.WriteBuffer(Pointer(AnsiString(out5))^,Length(out5));

与

out1:=out1+#13#10; out2:=out2+#13#10; out3:=out3+#13#10;out4:=out4+#13#10; out5:=out5+#13#10;
FS.WriteBuffer(Pointer(AnsiString(out1))^,Length(out1));
FS.WriteBuffer(Pointer(AnsiString(out2))^,Length(out2));
FS.WriteBuffer(Pointer(AnsiString(out3))^,Length(out3));
FS.WriteBuffer(Pointer(AnsiString(out4))^,Length(out4));
FS.WriteBuffer(Pointer(AnsiString(out5))^,Length(out5));

将 CR/LF 附加到每一行。