在 Delphi 2010 中将字符串写入 TFileStream

Question

我的 Delphi 2007 代码如下所示：

procedure WriteString(Stream: TFileStream; var SourceBuffer: PChar; s: string);
begin
  StrPCopy(SourceBuffer,s);
  Stream.Write(SourceBuffer[0], StrLen(SourceBuffer));
end;

我这样称呼它：

var
  SourceBuffer : PChar;
  MyFile: TFileStream;

....

SourceBuffer := StrAlloc(1024);
MyFile := TFileStream.Create('MyFile.txt',fmCreate);
WriteString(MyFile,SourceBuffer,'Some Text');
....

这在 Delphi 2007 中有效，但在 Delphi 2010 中给了我很多垃圾字符。我知道这是由于 unicode 合规性问题，但我不知道如何解决这个问题。

这是我迄今为止尝试过的：

• 更改数据类型 SourceBuffer（以及参数 WideString 预期）到 PWideChar

• suggestions listed here中的每一位

我做错了什么？

Answer 1

您不需要单独的缓冲区来将字符串写入流。可能最简单的方法是将字符串编码为 UTF8，如下所示：

procedure TStreamEx.writeString(const data: string);
var
   len: cardinal;
   oString: UTF8String;
begin
   oString := UTF8String(data);
   len := length(oString);
   self.WriteBuffer(len, 4);
   if len > 0 then
      self.WriteBuffer(oString[1], len);
end;

function TStreamEx.readString: string;
var
   len: integer;
   iString: UTF8String;
begin
   self.readBuffer(len, 4);
   if len > 0 then
   begin
      setLength(iString, len);
      self.ReadBuffer(iString[1], len);
      result := string(iString);
   end;
end;

我已将 TStreamEx 声明为 TStream 的类助手，但将它们重写为一个单独的过程并像您的示例一样运行应该不会太难。

Answer 2

Delphi 2010 有一个很好的解决方案，记录在这里：

http://docwiki.embarcadero.com/CodeExamples/en/StreamStrRdWr_%28Delphi%29

var
  Writer: TStreamWriter;
...

  { Create a new stream writer directly. }
  Writer := TStreamWriter.Create('MyFile.txt', false, TEncoding.UTF8);
  Writer.Write('Some Text');

  { Close and free the writer. }
  Writer.Free();