使用 NASM 构建 KMP 前缀

Question

我正在尝试在 NASM 中实现以下 C 代码，然后将其链接到 C 程序并从那里运行。

我正在尝试实现的代码：

   void preKmp(char *x, int m, int kmpNext[]) {
   int i, j;

   i = 0;
   j = kmpNext[0] = -1;
   while (i < m) {
      while (j > -1 && x[i] != x[j])
         j = kmpNext[j];
      i++;
      j++;
      if (x[i] == x[j])
         kmpNext[i] = kmpNext[j];
      else
         kmpNext[i] = j;
   }
}

我在 NASM 中与我的 cmets 的尝试：

;nasm -f elf32 table.asm -o table.o

segment .bss
kmpNext resd 256


segment .text
global table

table:
    push ebp          ;save the old base pointer value
    mov  ebp,esp      ;base pointer <- stack pointer

    mov eax,[ebp+8]     ;function argument, eax = search_string
    mov ecx, 0          ;i = 0
    mov edx, -1         ;j = -1
    mov [kmpNext], edx  ;kmpNext[0] = -1
oWhile:
    cmp byte [eax + ecx*4], 0  ;end of array control
    je finished
iWhile:
    cmp edx, -1
    jle pass
    mov edi,[eax + ecx*4] ;edi = x[i]
    mov esi,[eax + edx*4] ;esi = x[j]
    cmp edi, esi
    je pass
    mov edx, [kmpNext +edx*4] ;j = kmpNext[j]
pass:
    inc ecx
    inc edx
    mov edi,[eax + ecx*4] ;edi = x[i]
    mov esi,[eax + edx*4] ;esi = x[j]
    cmp edi, esi
    jne store
    mov edi, [kmpNext + edx*4]  ;edi = kmpNext[j]
    mov [kmpNext + ecx*4], edi  ;kmpNext[i] = edi
store:
    mov [kmpNext + ecx*4], edx  ;kmpNext[i] = j
    jmp oWhile
finished:
    mov eax, kmpNext;

    pop ebp
    ret

我在其中调用 NASM 函数的 C 代码：

#include <stdio.h>
#include <string.h>

int* table(char *str);

int main(void)
{
    char str[256];
    int i, n, *pre;

    printf("Enter string: ");
    scanf("%s" , str) ;
    n = strlen(str);
    pre = table(str);
    for (i = 0; i < n; i++){
      printf("%d ", pre[i]);

    }
    printf("\n");
    return 0;
}

一切都编译并运行正常，但输出错误。例如，

对于“可口可乐”，我应该得到：-1 -1 0 -1 0 1 -1 -1

我得到的地方：-1 0 0 0 0 0 0 0

有人能指出我在 NASM 代码中的错误吗？

我怀疑问题出在这一行：

mov esi, [eax + ecx*4]

当我运行调试器时，我没有看到 esi 的内容发生变化。

Answer 1

1) 主要错误是，str 是字节数组（8 位），但您将其视为整数数组（32 位）。

2) 有两个 while 循环。 两个都需要跳回来重复。

3) store 是 else 的情况。如果if-case 适合，它不能运行。在这种情况下，适合跳转到oWhile。

这是修正后的函数：

table:
    push ebp          ;save the old base pointer value
    mov  ebp,esp      ;base pointer <- stack pointer

    push edi          ; callee saved
    push ebx

    mov eax,[ebp+8]     ;function argument, eax = search_string
    mov ecx, 0          ;i = 0
    mov edx, -1         ;j = -1
    mov [kmpNext], edx  ;kmpNext[0] = -1

oWhile:
    cmp byte [eax + ecx], 0  ;end of array control
    je finished

iWhile:
    cmp edx, -1
    jle pass

    mov bl,[eax + ecx] ; bl = x[i]
    mov bh,[eax + edx] ; bh = x[j]
    cmp bl, bh

    je pass
    mov edx, [kmpNext +edx*4] ;j = kmpNext[j]
    jmp iWhile

pass:
    inc ecx
    inc edx

    mov bl,[eax + ecx] ; bl = x[i]
    mov bh,[eax + edx] ; bh = x[j]
    cmp bl, bh

    jne store
    mov edi, [kmpNext + edx*4]  ;edi = kmpNext[j]
    mov [kmpNext + ecx*4], edi  ;kmpNext[i] = edi

    jmp oWhile

store:
    mov [kmpNext + ecx*4], edx  ;kmpNext[i] = j
    jmp oWhile

finished:
    mov eax, kmpNext;

    pop ebx
    pop edi
    pop ebp
    ret

Answer 2

oWhile:
    cmp byte [eax + ecx*4], 0

这不等于while (i < m)。应该是：

oWhile:
    cmp ecx,[ebp+12]
    jge finished

您不应该在返回之前mov eax, [kmpNext]；它是一个 void 函数（虽然没有害处 - 编译器会忽略返回值）。

此外，您可能需要保存 edi 和 esi 以及可能的其他寄存器，否则调用者可能会感到困惑。检查你的 C 编译器手册。