在 windows 下的 perl 中从命令中捕获 STDERR 和管道 STDOUT

Question

我正在编写一个 Perl 脚本，它使用 system 来运行这样的外部命令管道：

system( "command1 | command2 | command3 > outfile" );

现在我想将所有这些命令中的 STDERR 捕获到一个文件中。这适用于 OS X：

system( "command1 2> error.log | command2 2> error.log | command3 2> error.log > outfile" );

但不是在 Windows 中，我得到错误：

“该进程无法访问该文件，因为它正被另一个进程使用”

有什么解决方法吗？我需要它是可移植的，所以如果可能的话，我想避免使用模块。 提前致谢。

Answer 1

没有外壳，没有临时文件，也没有核心之外的任何东西。

use strict;
use warnings;

use IPC::Open3 qw( open3 );

my @pids;
{
   my @cmd1 = ( 'perl', '-E',  q{say for qw( ABC DEF );}     );
   my @cmd2 = ( 'perl', '-pe', q{$_=lc; warn(qq{x\n});}      );
   my @cmd3 = ( 'perl', '-pe', q{$_=ucfirst; warn(qq{y\n});} );

   my $nul = $^O eq 'MSWin32' ? 'nul' : '/dev/null';

   open(local *CHILD_STDIN,  '<', $nul       ) or die $!;
   open(local *CHILD_STDOUT, '>', 'outfile'  ) or die $!;
   open(local *CHILD_STDERR, '>', 'error.log') or die $!;

   push @pids, open3('<&CHILD_STDIN', local *PIPE1,     '>&CHILD_STDERR', @cmd1);
   push @pids, open3('<&PIPE1',       local *PIPE2,     '>&CHILD_STDERR', @cmd2);
   push @pids, open3('<&PIPE2',       '>&CHILD_STDOUT', '>&CHILD_STDERR', @cmd3);

   *CHILD_STDIN if 0;  # Silence warning. Already closed by open3.
   *PIPE1       if 0;  # Silence warning. Already closed by open3.
   *PIPE2       if 0;  # Silence warning. Already closed by open3.

   close(CHILD_STDOUT);
   close(CHILD_STDERR);
}

waitpid($_, 0) for @pids;

Answer 2

那是因为 '>' 不喜欢共享文件。 给流水线的每个阶段自己的错误日志，然后在流水线完成后执行类似这样的操作：

  system("cat error1.log erorr2.log error3.log > error.log");

这是一种独立于平台的方式来聚合日志：

my @error_logs = qw( error1.log error2.log error3.log );
open my $errlog, ">>", "error.log" || die "probelm opening error log: $!";

foreach my $sublog ( @error_logs ) {
   open my $fh, "<", $sublog || die "oh boy: $sublog: $!";
   print "$sublog:"
   print $errlog while $fh;
   close $fh;
}

close $errlog;

但如果您决定采用这种方式，也存在 IO::Cat 和 File::Cat。

---

1)更正了不共享文件的自私者的名称。

2) 添加日志文件收集