Delphi - 通过值访问类字符串属性

Question

我定义了一个只包含字符串作为属性的类，我需要根据其值获取属性名称，如下例所示。在示例中只有 3 个属性，在现实生活中的类中几乎有 1000 个。问题是这个类被大量使用，我想知道是否可以更快地通过其值获取属性名称。

unit Unit5;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs,RTTI, StdCtrls, Diagnostics;

type
  TConstDBElem = class
  public
    CCFN_1 : String;
    CCFN_2 : String;
    CCFN_3 : String;
    constructor Create;
  end;

  TForm5 = class(TForm)
    Memo1: TMemo;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  end;

var
  Form5: TForm5;
  Obj: TConstDBElem;

implementation


{$R *.dfm}

procedure TForm5.Button1Click(Sender: TObject);
var iPos:Integer;
    timer:TStopwatch;
    Function GetName(const DBElemInstance : TConstDBElem; valueName: string) : string;
  var
    vrttiContext: TRttiContext;
    vrttiField : TRttiField;
    vType : TRttiType;
  begin
      vType := vrttiContext.GetType(TConstDBElem);

      for vrttiField in vType.GetFields do
        if (vrttiField.GetValue(DBElemInstance).ToString = valueName) then
        begin
           result := vrttiField.Name;
         end;
  end;

begin
  timer := TStopwatch.Create;
  timer.Start;
  Memo1.Lines.Clear;
  for iPos := 0 to 100000 do
    GetName(Obj,'TEST3');
  timer.Stop;
  Memo1.Lines.Add(FloatToStr(timer.Elapsed.TotalSeconds));
end;

constructor TConstDBElem.Create;
begin
  CCFN_1 := 'TEST1';
  CCFN_2 := 'TEST2';
  CCFN_3 := 'TEST3' ;
end;

initialization
  Obj := TConstDBElem.Create;

finalization
  Obj.Free;


end.

是的，我知道这是一个非常糟糕的设计，不应该这样做。是否有任何选项可以加快搜索速度？

Answer 1

当GetName() 找到匹配项时，它并没有停止循环，因此它会继续搜索更多匹配项。分配函数的 Result 不会退出函数，就像您显然认为的那样。因此，GetName() 最终返回 last 匹配，而不是 first 匹配。当找到第一个匹配项时，循环应该调用Exit：

Function GetName(const DBElemInstance : TConstDBElem; valueName: string) : string;
var
  vrttiContext: TRttiContext;
  vrttiField : TRttiField;
  vType : TRttiType;
begin
  vType := vrttiContext.GetType(TConstDBElem);

  for vrttiField in vType.GetFields do
    if (vrttiField.GetValue(DBElemInstance).ToString = valueName) then
    begin
      result := vrttiField.Name;
      Exit; // <-- add this
    end;
end;

或者，使用带有参数的Exit() 版本：

Function GetName(const DBElemInstance : TConstDBElem; valueName: string) : string;
var
  vrttiContext: TRttiContext;
  vrttiField : TRttiField;
  vType : TRttiType;
begin
  vType := vrttiContext.GetType(TConstDBElem);

  for vrttiField in vType.GetFields do
    if (vrttiField.GetValue(DBElemInstance).ToString = valueName) then
    begin
      Exit(vrttiField.Name); // <-- assigns Result and exits at the same time
    end;
end;

在您的简单示例中，搜索 3 个字段所浪费的时间几乎不会引起注意，但在搜索 1000 个字段时，它会有所不同。

Answer 2

您在评论中声明这些值在运行时永远不会改变。在这种情况下，您可以在启动时简单地构建一个字典，其中属性值作为字典键，属性名称作为字典值。

我假设类的所有实例都具有相同的属性值。如果不是这种情况，那么每个实例都需要一本字典。

Answer 3

这是一个“糟糕的设计”，因为有人编写了一个他们将其视为 C 风格结构的类。正如已经说过的，类中没有定义任何属性，只有一堆公共数据成员，也就是“字段”。

没有封装，因此您为更改结构所做的任何事情都可能对使用它的任何单元产生深远的影响。我同意用 TStringList 或 TDictionary 替换 IMPLEMENTATION 会很聪明，但是......没有要遵守的接口！您有 1000 多个对公共数据成员的硬连线引用。

（上次我看到这样的东西是一群 VB 程序员编写的一些代码，他们编写的类好像是包含公共数据成员的 C 风格结构，然后他们编写外部函数来访问数据，只是就像你在 C 中所做的那样。只有它们也将业务逻辑隐藏在访问器方法中，这会导致随机的代码片段直接引用类的数据成员。）

副手，我会说你完全误用了 RTTI 代码。当然，上面的优化会提高性能，但那又如何呢？这是错误的解决方案！

如果你真的想重构这个（你当然应该！），首先我会通过将公共更改为私有来看看这个可怜的类的使用有多广泛，看看你得到了多少错误。

然后我会从 TStringList 派生它，删除所有本地字段，并将 GetName 函数移动到类中：

type
  TConstDBElem = class( TStringList )
  public
    constructor Create;
    function GetName( aName : string ) : string;
  end;

现在，如果我正确解释了您的示例，您希望这样做来初始化对象：

constructor TConstDBElem.Create;
begin
  Add( 'TEST1=CCFN_1' );
  Add( 'TEST2=CCFN_2' );
  Add( 'TEST3=CCFN_3' );
end;

然后调用 obj.GetName() 替换其他单元中的所有引用：

function TConstDBElem.GetName( aName : string ) : string;
begin
  Result := Values[aName];
end;

您正在用obj.GetName('TEST1') 替换对obj.CCFN_1 (?) 或GetName(obj,'TEST1') 的引用。

（也许我在这一点上完全偏离了基础。对不起，但我只是不明白你是如何从这个例子中使用这个类的，而且它对我来说没有多大意义.如果你说你在什么之间映射会更有意义。我的意思是......谁需要从与其关联的值中查找本地字段名称？一旦找到它你会怎么处理它? 写这篇文章的人必须经历一些令人难以置信的扭曲才能使代码正常工作，因为他/她在设计时肯定不了解 OOP！）

此时，您将成功地将此类（其他单元）的客户端与其内部实现分离，并将这些引用替换为对类中定义的接口（方法）的调用。

然后你可以做一些测试来看看如果你改变实现会发生什么，比如从 TStringList 到 TDictionary。但是无论您如何切片，我都无法想象 TStringList 或 TDictionary 会比您在示例中滥用 RTTI 系统的方式慢。 :)