如何使 Perl 6 语法产生多个匹配项（例如 :ex 和 :ov）？

Question

我想让grammar 做这样的事情：

> "abc" ~~ m:ex/^ (\w ** 1..2) (\w ** 1..2) $ {say $0, $1}/
｢ab｣｢c｣
｢a｣｢bc｣

或者像这样：

> my regex left { \S ** 1..2  }
> my regex right { \S ** 1..2  }
> "abc" ~~ m:ex/^ <left><right> $ {say $<left>, $<right>}/
｢ab｣｢c｣
｢a｣｢bc｣

这是我的grammar：

grammar LR {
  regex TOP {
    <left> 
    <right>
  }
  regex left {
    \w ** 1..2 
  }
  regex right {
    \w ** 1..2 
  }
}

my $string = "abc";
my $match = LR.parse($string);
say "input: $string";
printf "split: %s|%s\n", ~$match<left>, ~$match<right>;

它的输出是：

$ input: abc
$ split: ab|c

所以，<left> 只能是贪婪，没有给<right>。我应该如何修改代码以匹配两种可能的变体？

$ input: abc
$ split: a|bc, ab|c

Answer 1

由于Grammar.parse 只返回一个Match 对象，您必须使用不同的方法来获取所有匹配项：

sub callback($match) {
    say $match;
}
grammar LR {
    regex TOP {
        <left> 
        <right>
        $
        { callback($/) }
        # make the match fail, thus forcing backtracking:
        <!>
    }
    regex left {
        \w ** 1..2 
    }
    regex right {
        \w ** 1..2 
    }
}

LR.parse('abc');

通过调用<!> 断言（总是失败）使匹配失败会强制先前的原子回溯，从而找到不同的解决方案。当然，这会降低语法的可重用性，因为它在语法的常规调用约定之外工作。

请注意，对于调用者来说，LR.parse 似乎总是失败；您将所有匹配项作为对回调函数的调用。

一个稍微好一点的 API（但下面的方法相同）是使用 gather/take 来获取所有匹配的序列：

grammar LR {
    regex TOP {
        <left> 
        <right>
        $
        { take $/ }
        # make the match fail, thus forcing backtracking:
        <!>
    }
    regex left {
        \w ** 1..2 
    }
    regex right {
        \w ** 1..2 
    }
}

.say for gather LR.parse('abc');

Answer 2

我认为 Moritz Lenz，昵称 moritz，即将出版的新书 "Parsing with Perl 6 Regexes and Grammars" 的作者，是要问这个问题的人。我可能应该让他回答这个问题...

注意事项

如果有人考虑尝试修改 grammar.parse 以使其支持 :exhaustive，或以其他方式破解事物以执行 @evb 想要的操作，以下文档可能有用的灵感/指导是我从探索相关推测文档中收集的（ S05) 并搜索 #perl6 和 #perl6-dev irc 日志。

7 年前 Moritz 添加了an edit of S05：

仅影响调用行为而不影响正则表达式本身的 [regex] 修饰符 [例如 :exhaustive] 可能只出现在涉及调用的构造上（如 m// [或 grammar.parse]），而不是在rx// [或regex { ... }]。

([例如:exhaustive]、[或grammar.parse]和[或regex { ... }]位是我在这个SO答案中添加的推断/解释/推测。它们不在链接源中.)

5 年前 Moritz expressed interest in implementing :exhaustive 用于匹配（而非解析）特征。不到 2 分钟后，jnthn 展示了一个单班轮，演示了他猜测他会如何接近它。不到 30 分钟后，莫里茨发布了a working prototype。 final version landed 7 days later。

1 年前 Moritz 在 #perl6 上说（强调由我添加）："regexes and grammars aren't a good tool to find all possible ways to parse a string"。

Hth.