彭博数据需要时间加载到 Excel-VBA

Question

我目前使用彭博 API 编写 this Excel VBA code。我正在尝试使用 VBA 将数据从 Bloomberg 提取到 Excel 中。这工作正常，但问题是我有另一个宏，然后从 Bloomberg 复制数据并将其粘贴到另一张表中。

如果数据还没有全部从 Bloomberg 输出，那么我最终没有足够的数据来复制然后粘贴到另一张表中。

目前，我正在使用这行代码：

Application.OnTime Now + TimeValue("00:01:45"), "RunAll"

在运行第一个宏 1 分 45 秒后等待，直到运行剩余的宏。它很有用，但时间太长了。问题是这与数据输出所需的时间有关。

是否有任何其他更有效的方法可以通过确保数据更快地输出到 Excel 中来更快地提取彭博数据？

Answer 1

处理它的一种方法是，当您启动第二个复制数据的宏时，检查中点单元格是否为空（类似于 A100？？在这里查看您的代码会有所帮助...） .如果是这样，请等待 10 秒钟并再次检查。这将迫使第二个宏在第一个宏赶上时保持在持有模式中。

但请注意，我会设置最大循环数，否则如果该数据由于某种原因没有下载，它不会挂断您的机器。

更新 1：

我写了下面的代码来完成你想要做的事情。您需要在当前代码中处理几件事，但我特意将其设为重注释，以便您能够遵循。让我知道这是否适合您。

Public boolBloombergCompleted As Boolean

Sub GetBloombergData()

    'add this line after the data grab is complete
    boolBloombergCompleted = True
End Sub


Sub WriteData()
    Dim iRow As Integer
    Dim boolTimeOut As Boolean

    'change the last number as fit, make sure it's larger than the number of rows of data you're pulling in though
    For iRow = 1 To 1000  

        ' Check to see if the cell is blank
        If Sheet1.Cells(iRow, 1) = vbNullString Then
            ' If the cell is blank and GetBloombergData has completed then exit sub
            If boolBloombergCompleted = True Then
                Exit Sub: Debug.Print "WriteData completed"
            Else
                ' Call the wait function below
                boolTimeOut = WaitForDataGrabToCatchUp(Sheet1.Cells(iRow, 1))
                If boolTimeOut = True Then GoTo TimeOutErr:
            End If
        End If

        ' < Add your code to write data in here >

    Next iRow

    Exit Sub

TimeOutErr:
    MsgBox "The write sub timed out while waiting for data to load", vbExclamation

End Sub

Function WaitForDataGrabToCatchUp(rng As Range) As Boolean
    Dim StartTime1 As Long
    Dim StartTime2 As Long
    Dim PauseTime As Long
    Dim StopTime As Long

    ' Set the amount of time to pause between checking the spreadsheet for updates
    PauseTime = 5 'seconds

    ' Set the maximum amount of time to wait before timing out
    StopTime = 60 'seconds

    ' StartTime1 is used for calculating overall time
    StartTime1 = Timer

    Do While rng = vbNullString
        ' check if the StopTime has been reached
        If Timer - StartTime1 > StopTime Then
            WaitForDataGrabToCatchUp = True
            Exit Function
        Else
           ' loop for amount of PausedTime (the DoEvents part here is key to keep the data grab moving)
            StartTime2 = Timer
            Do While Timer < StartTime2 + PauseTime
                Debug.Print Timer - StartTime1
                DoEvents
            Loop
        End If
    Loop

    WaitForDataGrabToCatchUp = False ' means it did not time out

End Function