perl如何从C头文件中提取#define'd数字

Question

我正在寻找一个 Perl sn-p 来将 C 标头中包含的数字 100 打印到终端。

#ifndef VERSIONS_H
#define VERSIONS_H

#define __SOFTWARE_REVISION__ 100

#endif

我可以提取#define 行，但是数字。

#!perl -w
use warnings;
use strict;
my $line;
my $file = shift @ARGV;
open my $fh, "<", $file or die $!;
while (<$fh>) {
        print if /__SOFTWARE_REVISION__/;
}
close ($fh);

Answer 1

正则表达式匹配包含该文字短语的任何行，而不仅仅是定义它的位置。您需要更精确地指定线路，并捕获所需的数字。

代码还会继续不必要地循环文件。

还有一些调整

use warnings;
use strict;
use feature qw(say);

my $file = shift @ARGV;
die "Usage: $0 filename\n" if not $file or not -f $file;

open my $fh, '<', $file or die "Can't open $file: $!";

while (<$fh>) {
    if (/^\s*#\s*define\s+__SOFTWARE_REVISION__\s+([0-9]+)/) {
        say "Software revision: $1";
        last;
    }
}
close $fh;

如果版本可以不是整数，则将 [0-9]+ 替换为允许使用句点的模式 [0-9.]+，或者 [0-9.a-z] 如果版本控制中允许使用（小写）字母...或简单地替换为 \S+ .

我建议在手头参考perlre 完成教程perlretut。

---

我假设这种需求出现在 Perl 程序中（而不是 Perl 是为此选择的工具）。

不过，请注意，还有其他更系统的方法可以使用编译器检索此信息（例如，请参阅 rici 对 gcc 的评论）。

虽然在 Perl 脚本中使用 Perl 比使用系统更好，但 这种 情况可能是例外之一：使用外部命令可能比解析源代码更好文件，这是众所周知的危险任务。

Answer 2

这是一种使用正则表达式来捕获版本号（如果存在于一行中）的方法。请注意，正则表达式中的括号分隔捕获组，变量$1 用于访问捕获。

#!perl -w
use warnings;
use strict;

my $file = shift @ARGV;
open my $fh, "<", $file or die $!;

while (<$fh>) {
    print "$1\n" if /^#define +__SOFTWARE_REVISION__ +(\d+)$/;
}

close $fh;

输出：

100

正则表达式比你的更具选择性，它匹配一行中__SOFTWARE_REVISION__ 的任何实例。此正则表达式匹配行首的#define，后跟一个或多个空格，然后是__SOFTWARE_REVISION__，后跟一个或多个空格，最后是一个或多个数字捕获组。