Clojure 中 2D 游戏板的适当表示

Question

我正在使用 Clojure 开发一个小游戏作为学习练习。我想我已经确定了在任何特定时间将游戏状态表示为“可移动”列表和“地形”（棋盘方格）的 2D 向量向量。

在 95% 的时间里，我希望检查 2D 矢量似乎适合的特定正方形中的碰撞。但在少数情况下，我需要另辟蹊径——找到符合某些条件的单元格的 (x,y) 位置。第一次尝试是这样的：

(defn find-cell-row [fn row x y]
  (if (empty? row) nil
    (if (fn (first row)) [x y]
      (find-cell-row fn (rest row) (inc x) y))))

(defn find-cell [fn grid y]
  (if (empty? grid) nil
    (or (find-cell-row fn (first grid) 0 y)
        (find-cell (rest grid) (inc y)))))

(def sample [[\a \b \c][\d \e \f]])
(find-cell #(= % \c) sample 0) ;; => [2 0]

我尝试了一些更简洁的地图索引，但它很快就变得丑陋了，仍然没有给我想要的东西。是否有更惯用的方法来进行此搜索，或者使用不同的数据结构可能会更好地为我服务？也许是地图 { [x y] -> cell }？使用地图来表示矩阵对我来说感觉很不对 :)

Answer 1

对于这种事情，嵌套向量是很正常的，如果你使用 for 理解，扫描它既不难也不难看：

(let [h 5, w 10]
  (first
   (for [y (range h), x (range w)
         :let [coords [y x]]
         :when (f (get-in board coords))]
     coords)))

Answer 2

如果使用普通向量，那么您可以使用所有“常用”函数，并且可以根据需要提取 [x y]。

(def height 3)
(def width 3)

(def s [\a \b \c \d \e \f \g \h \i])

(defn ->xy [i]
    [(mod i height) (int (/ i height))])

(defn find-cell 
    "returns a vector of the [x y] co-ords of cell when
     pred is true"
    [pred s]
    (let [i (first (keep-indexed #(when (pred %2) %1) s))]
      (->xy i)))

(find-cell #(= \h %) s)
;=> [1 2]

(defn update-cells 
    "returns an updated sequence s where value at index i
     is replaced with v. Allows multiple [i v] pairs"
    [s i v & ivs]
    (apply assoc s i v ivs))

(update-cells s 1 \z)
;=> [\a \z \c \d \e \f \g \h \i]

(update-cells s 1 \p 3 \w)
;=> [\a \p \c \w \e \f \g \h \i]