GnuPlot :: 绘制以非常规格式记录的 3D

Question

我想准备一个脚本文件来绘制一些动力学光谱结果的 3D 图。在实验中，溶液的吸收光谱在从 t₀ 到 t_f 的增加时间依次测量，时间 Δt 不断增加。 该图将显示吸光度 (Z) 随波长和时间的变化。

使用 UV-VIS 光谱仪记录数据并保存为 CSV 文本文件。

该文件包含一个表格，其中第一列是光谱的波长。之后，为每个测量的光谱添加一列，列的数量取决于总时间和测量之间的时间间隔。每个光谱的时间出现在标题行中。

我想知道是否可以用最少的预格式化直接绘制数据，而无需以更标准的 XYZ 格式重写数据。

数据文件的结构是这样的

标题；紫外-可见分光镜
评论;
日期; 23/10/2018 16:41:12
操作员;实验室
系统名称；未定义
波长（nm）； 0分钟； 0,1 分钟； 0,2 分钟； 0,3 分钟； ... 28,5 分钟
400,5551; 1,491613E-03； 1,810312E-03； 2,01891E-03； ... 4,755786E-03
... ... ... ... ... ...
799,2119; -5,509266E-04； 3,26314E-04； -4,319865E-04； ... -5,087912E-04
(EOF)

此文件kinetic_spectroscopy.csv 中包含样本数据的副本。

谢谢。

Answer 1

您的数据是 gnuplot 可接受的形式，但说服程序将其绘制为每个波长一条线而不是网格表面更困难。首先让我们确定文件可以读取和打印。以下命令应读取 x/y 坐标（x = 第一行，y = 第一列）和 z 值以构建表面。

DATA = 'espectros cinetica.csv'
set datafile separator ';'  # csv file with semicolon

                            # Your data uses , as a decimal point.
set decimal locale          # The program can handle this if your locale is correct.
show decimal                # confirm this by inspecting the output from "show".

set title DATA
set ylabel "Wavelength"
set xlabel "Time (min)"
set xyplane 0
set style data lines

splot DATA matrix nonuniform using 1:2:3 lc palette

您的数据实际上看起来没问题。对于较少数量的扫描，它可能不是您想要的。为了绘制单独的线，每次扫描一条，我们可以将其分解为一系列线图而不是单个曲面图：

 DATA = 'espectros cinetica.csv'
 set datafile separator ";"
 set decimal locale
 unset key
 set title DATA
 set style data lines
 set ylabel "Wavelength"
 set xlabel "Time (min)"
 set xtics offset 0,-1      # move labels away from axis

 splot for [row=0:*] DATA matrix nonuniform every :::row::row using 1:2:3

这是我从您的数据文件的前 100 行得到的。行数据按 gnuplot 线型顺序着色。其他着色方案是可能的。