如何使用 TSQL 截断数据库中除查找表之外的所有表？

Question

在 SQL Server 2012 及更低版本中使用 TSQL 从所有表中删除除查找表数据之外的所有数据的最佳方法是什么？ 我希望 TSQL 识别并排除查找表，然后为其他表创建截断表语句。

** 几乎有a similar question，但它会截断所有表格。

Answer 1

查找表和非查找表在技术特征上相似。只是在功能上它们是不同的。因此，不会有具体的标准来区分它们。

Answer 2

除非您从设计的角度设置自己能够做到这一点，例如将所有“查找”表放在“lkup”模式或类似性质的东西中，我认为没有办法做到这一点。正如有人已经提到的，查找表与其他表一样。

Answer 3

我会通过首先以正确的顺序删除（依赖项）来自动使用 DELETE

1) 传递表名

2) 禁用你的外键

3) 清空删除所有表

4) 重新启用它们的键。

通过这种方式，您可以使用条件控制传递要“截断”的表名。

Answer 4

或者那会很重要：

ALTER PROCEDURE 
up_ResetEntireDatabase 
@IncludeIdentReseed BIT, 
@IncludeDataReseed BIT 
AS 

EXEC sp_MSForEachTable 'ALTER TABLE ? NOCHECK CONSTRAINT ALL' 
EXEC sp_MSForEachTable 'DELETE FROM ?'

 IF @IncludeIdentReseed = 1 
BEGIN 
EXEC sp_MSForEachTable 'DBCC CHECKIDENT (''?'' , RESEED, 1)' 
END 

EXEC sp_MSForEachTable 'ALTER TABLE ? CHECK CONSTRAINT ALL' 

IF @IncludeDataReseed = 1 
BEGIN 
-- Populate Core Data Table Here 
END 

GO

然后一旦准备好执行就很简单了：

EXEC up_ResetEntireDatabase 1, 1

Answer 5

我不确定您的意思是不是可以驱动这种情况的查找表。

构建一个简单的表，其中包含每个数据库表的名称并创建列，如果需要，您可以在执行脚本之前进行修改。

这些列可能只是告诉脚本是否截断该表或其他表的标志。

这样你（脚本）在读取表名时就会知道依赖关系。如果您在记录编号顺序中保持表顺序不变，则不需要索引。

只是另一个维护脚本。

Answer 6

因此，您希望截断具有外键的表，但单独保留引用表。应该这样做。

WITH CTE_fks
AS
(
    SELECT  obj.name AS FK_NAME,
            sch1.name AS [table_schema],
            tab1.name AS [table_name],
            col1.name AS [column],
            sch2.name AS [ref_table_schema],
            tab2.name AS [referenced_table],
            col2.name AS [referenced_column]
    FROM sys.objects obj
    INNER JOIN sys.foreign_key_columns fkc
        ON obj.object_id = fkc.constraint_object_id
    INNER JOIN sys.tables tab1
        ON tab1.object_id = fkc.parent_object_id
    INNER JOIN sys.schemas sch1
        ON tab1.schema_id = sch1.schema_id
    INNER JOIN sys.columns col1
        ON col1.column_id = parent_column_id AND col1.object_id = tab1.object_id
    INNER JOIN sys.tables tab2
        ON tab2.object_id = fkc.referenced_object_id
    INNER JOIN sys.schemas sch2
        ON tab2.schema_id = sch2.schema_id
    INNER JOIN sys.columns col2
        ON col2.column_id = referenced_column_id AND col2.object_id = tab2.object_id
)

SELECT  'TRUNCATE TABLE ' + QUOTENAME(A.TABLE_SCHEMA) + '.' + QUOTENAME(A.table_name) + ';'
FROM INFORMATION_SCHEMA.TABLES A
LEFT JOIN CTE_fks B
ON A.TABLE_NAME = B.referenced_table
AND A.TABLE_SCHEMA = B.ref_table_schema
WHERE A.TABLE_TYPE = 'BASE TABLE'
AND A.TABLE_NAME != 'sysdiagrams'
AND B.table_name IS NULL