Oracle 使用临时表或其他方法

Question

在 Oracle 中，需要在存储过程中多次重用查询结果。想知道临时表是否是推荐的方式或其他方式......

首先我根据某些输入参数创建一个结果集。

然后进行一些检查以查看表 1 中是否出现任何结果集行。简单的连接和计数就足够了。 如果 count > 0 则返回。 如果 count == 0 则我将结果集中的选定值（基于某些条件）插入表 1。

是否应该使用临时表或其他东西以获得最佳性能？

谢谢，

Answer 1

鉴于上次更新，您似乎需要在多个表中进行质量不同的插入，并在多个（不同）测试中使用昂贵查询的结果。

最好进行测试和基准测试（比较优缺点，以及临时表与其他方法的性能）。我将在此处包含另一种样式，它只是将结果拉入内存，可以根据需要在内存中查询它们（或迭代、计数等）

下面是一个例子：

-- 示例数据：

CREATE TABLE TABLE_1 (LOREM_IPSUM NUMBER);
INSERT INTO TABLE_1 VALUES (6);
COMMIT;

-- 保存数据的自定义类型

CREATE OR REPLACE TYPE EXPENSIVE_QUERY_TYPE IS OBJECT(LOREM_IPSUM NUMBER);
/
CREATE OR REPLACE TYPE EXPENSIVE_QUERY_RESULT IS TABLE OF EXPENSIVE_QUERY_TYPE;
/

-- 示例块：

DECLARE
    V_EXPENSIVE_RESULT EXPENSIVE_QUERY_RESULT := EXPENSIVE_QUERY_RESULT();
    V_TABLE_1_TEST INTEGER;
BEGIN
    SELECT EXPENSIVE_QUERY_TYPE(LEVEL)
    BULK COLLECT INTO V_EXPENSIVE_RESULT
    FROM DUAL
    CONNECT BY LEVEL <= 5;

    SELECT COUNT(*) INTO V_TABLE_1_TEST
        FROM TABLE_1
            WHERE EXISTS(SELECT 1 FROM TABLE(V_EXPENSIVE_RESULT) WHERE LOREM_IPSUM = TABLE_1.LOREM_IPSUM);

    IF V_TABLE_1_TEST > 0
        THEN
        RETURN;
        ELSE
        INSERT INTO TABLE_1
            SELECT LOREM_IPSUM FROM TABLE(V_EXPENSIVE_RESULT)
            WHERE MOD(LOREM_IPSUM,2) = 0;
    END IF;

END;
/

当 TABLE_1 最初只有一条值为 6 的记录时，这会插入 2 和 4（因为没有共享数据）。

...PL/SQL procedure successfully completed.
SELECT * FROM TABLE_1;
   LOREM_IPSUM
______________
             2
             4
             6

但是如果它在expensive_query 中包含任何内容（例如最初同时包含3 和6），则不会插入任何内容：

...PL/SQL procedure successfully completed.
SELECT * FROM TABLE_1;
   LOREM_IPSUM
______________
             3
             6