使用 XSLT 或任何其他方法的 XML 到 HTML 表答案

【问题标题】：XML to HTML Tables using XSLT or any other method使用 XSLT 或任何其他方法的 XML 到 HTML 表
【发布时间】：2020-01-20 09:13:16
【问题描述】：

我有一个包含以下 XML 数据的 XML 文件。

<group1>
<item1>val1</item1>
<item2>val2</item2>
<group2>
    <item3>val3</item3>
    <item4>val4</item4>
    <group3>
        <item5>val5</item5>
    </group3>
</group2>
<group2>
    <item3>val6</item3>
    <item4>val7</item4>
    <group3>
        <item5>val8</item5>
    </group3>
</group2>
<group4>
    <item6>val9</item6>
    <item7>val10</item7>
</group4>
<group4>
    <item6>val11</item6>
    <item7>val12</item7>
</group4>

像 HTML 表格一样

<table --for group1>
    <tr>
        <th>item1</th>
        <th>item2</th>
    </tr>
    <tr>
        <td>val1</td>
        <td>val2</td>
    </tr>
</table>

<table --for group2>
    <tr>
        <th>item3</th>
        <th>item4</th>
    </tr>
    <tr>
        <td>val3</td>
        <td>val4</td>
    </tr>
</table>

<table --for group3>
    <tr>
        <th>item5</th>
    </tr>
    <tr>
        <td>val5</td>
    </tr>
</table>

<table --for group2>
    <tr>
        <th>item3</th>
        <th>item4</th>
    </tr>
    <tr>
        <td>val6</td>
        <td>val7</td>
    </tr>
</table>

<table --for group3>
    <tr>
        <th>item5</th>
    </tr>
    <tr>
        <td>val8</td>
    </tr>
</table>

<table --for group4>
    <tr>
        <th>item6</th>
        <th>item7</th>
    </tr>
    <tr>
        <td>val9</td>
        <td>val10</td>
    </tr>
    <tr>
        <td>val11</td>
        <td>val12</td>
    </tr>
</table>

在 group1 中有两个 group2，其中有 group3。因此，每个 group2 应该是一个单独的表，后面有 group3 表。有两个 group4，但其中没有另一个组。所以两个 group4 应该在一个表中。

注意：每个组可以嵌套任意数量的组。

我想要实现的是在 Oracle bi 发布者数据模型表视图中显示查询结果。

能够通过为不同深度使用不同的 XSL 模板来实现固定深度，但不知道在深度不固定时如何实现。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
    <HTML>
        <BODY>
            <xsl:apply-templates />
        </BODY>
    </HTML>
</xsl:template>
<xsl:template match="/*">
    <TABLE BORDER="1">
        <TR>
            <xsl:for-each select="*/*">
                <xsl:choose>
                    <xsl:when test="child::*">
                        <!-- <h1>
                            <xsl:value-of select="local-name()" />
                        </h1> -->
                    </xsl:when>
                    <xsl:otherwise>
                        <!-- <h1>
                        <xsl:value-of select="local-name()" />
                    </h1> -->
                        <xsl:for-each select=".">
                            <TD>
                                <xsl:value-of select="local-name()" />
                            </TD>
                        </xsl:for-each>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:for-each>
            <xsl:apply-templates />
        </TR>
    </TABLE>
</xsl:template>
<xsl:template match="/*/*">
    <TR>
        <xsl:for-each select="*">
            <xsl:choose>
                <xsl:when test="child::*">
                    <h1>
                        <xsl:value-of select="local-name()" />
                    </h1>
                </xsl:when>
                <xsl:otherwise>
                    <td>
                        <xsl:apply-templates select="." />
                    </td>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each>
    </TR>
</xsl:template>
<!-- <xsl:template match="/*/*/*">
    <xsl:choose>
        <xsl:when test="child::*">
            <TABLE BORDER="1">
                <TR>
                    <xsl:for-each select="*/*">
                        <TD>
                            <xsl:value-of select="local-name()" />
                        </TD>
                    </xsl:for-each>
                </TR>
            </TABLE>
            <xsl:value-of select="." />
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="." />
        </xsl:otherwise>
    </xsl:choose>
</xsl:template> -->

【问题讨论】：

每个嵌套级别真的有不同的名称吗（例如 group1、group2、...、item1、item2、item3、...）？还是元素名称相同，您可以编写单个递归模板？
是的，他们有不同的名字

标签： javascript python xml xslt

【解决方案1】：

在大多数情况下，您似乎只想展平嵌套层次结构，因此为此使用递归。此外，要合并/分组最深层次，请使用分组，例如在 XSLT 1 中，使用 Muenchian 分组和键：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">

  <xsl:output method="html" indent="yes" version="5" doctype-system="about:legacy-doctype"/>

  <xsl:key name="table-group"
    match="*[* and not(*/*)]"
    use="concat(generate-id(..), '|', local-name())"/>

  <xsl:template match="*[*]">
      <table>
          <thead>
              <tr>
                  <xsl:apply-templates select="*[not(*)]" mode="header"/>
              </tr>
          </thead>
          <tbody>
              <tr>
                  <xsl:apply-templates select="*[not(*)]"/>
              </tr>
          </tbody>
      </table>
      <xsl:apply-templates select="*[*/*]"/>
      <xsl:apply-templates
        select="*[* and not(*/*)][generate-id() = generate-id(key('table-group', concat(generate-id(..), '|', local-name()))[1])]" mode="merge-groups"/>
  </xsl:template>

  <xsl:template match="*[not(*)]" mode="header">
      <th>
          <xsl:value-of select="local-name()"/>
      </th>
  </xsl:template>

  <xsl:template match="*[not(*)]">
      <td>
          <xsl:value-of select="."/>
      </td>
  </xsl:template>

  <xsl:template match="*[*]" mode="merge-groups">
      <table>
          <thead>
              <tr>
                  <xsl:apply-templates select="*[not(*)]" mode="header"/>
              </tr>
          </thead>
          <tbody>
              <xsl:apply-templates select="key('table-group', concat(generate-id(..), '|', local-name()))" mode="row"/>
          </tbody>
      </table>
  </xsl:template>

  <xsl:template match="*" mode="row">
      <tr>
          <xsl:apply-templates select="*"/>
      </tr>
  </xsl:template>

  <xsl:template match="/">
    <html>
      <head>
        <title>.NET XSLT Fiddle Example</title>
      </head>
      <body>
        <xsl:apply-templates/>
      </body>
    </html>
  </xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty-development.net/ncnu9AZ/1

如果您不熟悉 XSLT 1 中的 Muenchian 分组，请使用任何有关 XSLT 1 中 Muenchian 分组的教科书或在线介绍来熟悉该方法，一个在线资源是 http://www.jenitennison.com/xslt/grouping/muenchian.html。

在上述样式表中，由于需要对仅在父容器上下文中未进一步嵌套的元素进行分组，因此使用的键包括生成的父元素的 id (generate-id(...))。因此，在元素的上下文中调用key('table-group', concat(generate-id(..), '|', local-name())) 会为我们提供一个节点集，其中包含一组在同一个父节点中具有相同名称的元素。使用整个谓词[generate-id() = generate-id(key('table-group', concat(generate-id(..), '|', local-name()))[1])]，我们只需确定当前正在处理该节点集中文档顺序中的第一个元素。 generate-id() = generate-id(key(...)[1]) 基本上是 XSLT 1 的一种方式，将 XSLT 2 或更高版本中可以执行的操作表示为 . is key(...)[1]，即检查谓词中上下文元素的节点身份以及该 key(...) 返回的第一个节点打电话。

【讨论】：

请说明上述代码中[generate-id() = generate-id(key('table-group', concat(generate-id(..), '|', local-name()))[1])]的用途。