有没有人能够创建 PE COFF 和 ELF 的混合体？答案

【问题标题】：Has anyone been able to create a hybrid of PE COFF and ELF?有没有人能够创建 PE COFF 和 ELF 的混合体？
【发布时间】：2010-01-17 19:43:49
【问题描述】：

我的意思是单个二进制文件可以在 Win32 和 Linux i386 中运行吗？

【问题讨论】：

标签： linux winapi binary elf coff

【解决方案1】：

这是不可能的，因为这两种类型有冲突的格式：

PE文件的前两个字符必须是'M' 'Z'；
ELF 文件的前四个字符必须是'\x7f' 'E' 'L' 'F'。

显然，您无法创建一个同时满足两种格式的文件。

作为对多语言二进制文件既可以作为 16 位 COM 文件又可以作为 Linux ELF 文件的评论的回应，这是可能的（尽管 COM 文件实际上是 DOS 程序，而不是 Windows，当然也不是 Win32）。

这是我拼凑的一个 - 用 NASM 编译它。它之所以有效，是因为 ELF 文件 ('\x7f' 'E') 的前两个字节恰好也是有效的 8086 机器代码（一个 45 字节的相对跳转如果大于指令）。从 Brian Raiter 抄袭的最小 ELF 标头。

BITS 32
ORG 0x08048000

  ehdr:                                                 ; Elf32_Ehdr
                db      0x7F, "ELF", 1, 1, 1, 0         ;   e_ident
        times 8 db      0
                dw      2                               ;   e_type
                dw      3                               ;   e_machine
                dd      1                               ;   e_version
                dd      _start                          ;   e_entry
                dd      phdr - $$                       ;   e_phoff
                dd      0                               ;   e_shoff
                dd      0                               ;   e_flags
                dw      ehdrsize                        ;   e_ehsize
                dw      phdrsize                        ;   e_phentsize
                dw      1                               ;   e_phnum
                dw      0                               ;   e_shentsize
                dw      0                               ;   e_shnum
                dw      0                               ;   e_shstrndx
  ehdrsize      equ     $ - ehdr

times 0x47-($-$$) db    0

; DOS COM File code
BITS 16
    mov dx, msg1 - $$ + 0x100
    mov ah, 0x09
    int 0x21
    mov ah, 0x00
    int 0x21
  msg1:         db      `Hello World (DOS).\r\n$`

BITS 32
  phdr:                                                 ; Elf32_Phdr
                dd      1                               ;   p_type
                dd      0                               ;   p_offset
                dd      $$                              ;   p_vaddr
                dd      $$                              ;   p_paddr
                dd      filesize                        ;   p_filesz
                dd      filesize                        ;   p_memsz
                dd      5                               ;   p_flags
                dd      0x1000                          ;   p_align
  phdrsize      equ     $ - phdr

; Linux ELF code
  _start:
    mov eax, 4      ; SYS_write
    mov ebx, 1      ; stdout
    mov ecx, msg2
    mov edx, msg2_len
    int 0x80
    mov eax, 1      ; SYS_exit
    mov ebx, 0
    int 0x80
  msg2:         db      `Hello World (Linux).\n`
  msg2_len      equ     $ - msg2

  filesize      equ     $ - $$

【讨论】：

很酷，但是 Windows 的 16 位 .com 并使其以某种方式兼容 ELF 怎么样？
那么COM程序可以启动一个Windows .exe吗？那太棒了。
也许 COM 程序可以将一个完整的 Win32 二进制文件写入用户的临时目录，然后启动它？（或者甚至以某种方式在内存中这样做）。顺便说一句，对于那些想知道的人：不，16 位程序不会在 Win7+ 中运行。

【解决方案2】：

这两种格式完全不同，不太可能混合使用。

不过，Linux 支持通过“解释器”加载不同的可执行格式。这样编译的.exe文件包含CIL（编译的C#或其他.NET语言）可以直接在Linux下执行，例如。

【讨论】：

这到底是怎么发生的？你知道我们可以在 Windows 下执行一个 .txt 文件。
@est 嗯，是的，实际上有点相似，除了“执行”一个文本文件，您需要在命令行上指定“解释器”：“open foo.txt”使用例如，资源管理器（可能会产生 textedit）。我所说的是识别可执行文件的类型并使用名为 binfmt_misc 的系统直接加载适当的格式：“Binfmt_misc 提供了向内核注册其他二进制格式的能力 [...]。” (tat.physik.uni-tuebingen.de/~rguenth/linux/binfmt_misc.html) 这只是一个方便的功能，而不是魔术。

【解决方案3】：

当然。使用 Java。

【讨论】：

很抱歉这个简短的答案，但它被巧妙地设计成正好是 15 个字符。真正的答案是 ELF 与 COFF 格式几乎是您最不担心的。您还有完全不同的系统调用、共享库/dll 等。