Haskell ReadP 解析列表中的至少一个

Question

我尝试使用 ReadP 标准库解析命令（创建）。我的命令应该以字符串create 开头，然后至少包含一个单词/标签/到期，并可能包含一个选项。这是我的实际表达：

createExpr :: ReadP [Arg]
createExpr = do
  skipSpaces
  cmd <- SetCmd <$> cmdAliasExpr ["create", "add"]
  skipSpaces
  rest <-
    many1
    $   (AddWord <$> wordExpr)
    <|> (AddTag <$> addTagExpr)
    <|> (SetDue <$> dueExpr)
    <|> (AddOpt <$> optExpr)
  skipSpaces
  return $ cmd : rest

问题是，如果我只用一个选项调用create，它就可以很好地解析。但它不应该，因为我希望至少有一个词/标签/到期。我该如何表达？

---

[编辑] 感谢@M. Aroosi，我找到了解决方案。

事实上，我用错了运算符。 <++，本地、独家、偏左的选择，更符合我的需求。一旦一个表达式被匹配，它不应该检查其他的：

notAnOpt arg = case arg of
  AddOpt _ -> False
  _        -> True


createExpr :: ReadP [Arg]
createExpr = do
  skipSpaces
  cmd <- SetCmd <$> cmdAliasExpr ["create", "add"]
  skipSpaces
  rest <-
    many1
    $   (AddTag <$> addTagExpr)
    <++ (SetDue <$> dueExpr)
    <++ (AddOpt <$> optExpr)
    <++ (AddWord <$> wordExpr)
  skipSpaces
  guard $ isJust $ find notAnOpt rest
  return $ cmd : rest

Answer 1

一个简单的解决方案是使用来自Control.Monad 的guard。
假设像isOpt :: Arg -> Bool 这样的函数类似于

isOpt :: Arg -> Bool
isOpt (AddOpt _) = True
isOpt _          = False 

然后您对createExpr 的定义更改为

createExpr :: ReadP [Arg]
createExpr = do
    skipSpaces
    cmd <- SetCmd <$> cmdAliasExpr ["create", "add"]
    skipSpaces
    rest <-
      many1
      $   (AddWord <$> wordExpr)
      <|> (AddTag <$> addTagExpr)
      <|> (SetDue <$> dueExpr)
      <|> (AddOpt <$> optExpr)
    guard $ at_least_one_non_optional rest
    skipSpaces
    return $ cmd : rest
  where at_least_one_non_optional = not . null . filter (not . isOpt)

guard 在其参数为 False 时基本上会使解析器失败，更一般地说，当参数为 False 时，它通过返回 empty 与任何 Alternative 一起工作。