如何将文本从 Excel 发送到一个单词（单元格）为粗体的 Word？

Question

我有一个包含 28 列数据的电子表格。根据哪些列有数据，通过使用 if 语句创建一个句子。一旦创建了句子，它就会被发送到 Word 文档。其中两个单元格中的数据需要格式化，当输出到 Word 时，A 列单元格需要加粗并加下划线，而另一个则简单地加下划线。这些单元格没有在 Excel 中格式化（尽管如果它更容易我可以更改它）。 Excel 只是保存数据，因为它是通过 Word 呈现给其他人的，它需要格式化以使读者受益。我知道如何将数据输出到 Word，但由于这是我第一次这样做，我不知道如何传递格式。我在想也许是通过选择性粘贴，但我又不知道该怎么做。以下是我的代码的适用部分。

一个名为 strLineofText 的字符串由单元格中的数据组成。随着单元格 A 和单元格 I 添加到字符串中，它们需要格式化为单元格 A 数据为粗体和下划线。我只包括下面适用于单元格 A 的部分。

Const strSHEET_NAME = "Sheet1"

Dim strLineOfText As String       
Dim blnNewApp As Boolean
Dim wordApp As Object
Dim wordDoc As Object
Dim j As Long

On Error Resume Next
Set wordApp = GetObject(, "Word.Application")

On Error GoTo ErrorHandler
If wordApp Is Nothing Then
    Set wordApp = CreateObject("Word.Application")
    blnNewApp = True
End If

Set wordDoc = wordApp.Documents.Add()

With ThisWorkbook.Sheets(strSHEET_NAME)
    For j = 2 To .Cells(.Rows.Count, "A").End(xlUp).Row

        strLineOfText = .Cells(j, "A").Text & ", enlisted " & .Cells(j, "B") & ", served " & .Cells(j, "C") & ", " & .Cells(j, "D") & ", " & .Cells(j, "E")

        wordApp.Selection.TypeText strLineOfText
        wordApp.Selection.TypeParagraph
    Next j
End With

wordApp.Visible = True
AppActivate wordApp.Caption

Answer 1

为什么不分解字符串并在部分之间切换格式？ 这是您的代码，已调整：

With ThisWorkbook.Sheets(strSHEET_NAME)
    For j = 2 To .Cells(.Rows.Count, "A").End(xlUp).Row

        wordApp.Selection.Font.Bold = True
        wordApp.Selection.Font.Underline = True

        wordApp.Selection.TypeText .Cells(j, "A").Text

        wordApp.Selection.Font.Bold = False
        wordApp.Selection.Font.Underline = False

        wordApp.Selection.TypeText ", enlisted " & .Cells(j, "B") & ", served " & .Cells(j, "C") & ", " & .Cells(j, "D") & ", " & .Cells(j, "E")

    Next j
End With

Answer 2

一般来说，为了弄清楚这样的事情，使用 Excel 中的宏记录器将为您提供基本的代码块，然后您可以对其进行清理和简化。

假设您在单元格“A1”中有以下文本：

This is a test of bold face. 

并且您想以粗体突出显示“测试”一词。此代码是宏记录器生成的代码的略微清理版本：

With Range("A1").Characters(Start:=11, Length:=4).Font
    .Name = "Calibri"
    .FontStyle = "Bold"
    .Size = 11
    .Strikethrough = False
    .Superscript = False
    .Subscript = False
    .OutlineFont = False
    .Shadow = False
    .Underline = xlUnderlineStyleNone
    .ThemeColor = xlThemeColorLight1
    .TintAndShade = 0
    .ThemeFont = xlThemeFontMinor
End With

实际上，您可以省略除“.FontStyle = Bold”选项之外的所有内容，但我想包含这些选项，以便您可以看到使用这种技术几乎可以控制文本格式的任何属性。

格式化文本后，您可以轻松地剪切和粘贴到 Word。