Biapplicative 和 Bimonad？

Question

Haskell 的Data.Bifunctor 基本上是：

class Bifunctor f where
  bimap :: (a -> c) -> (b -> d) -> f a b -> f c d 

我也可以找到Biapply。我的问题是，为什么没有完整的双层次结构（bierarchy？），例如：

class Bifunctor f => Biapplicative f where
  bipure :: a -> b -> f a b
  biap :: f (a -> b) (c -> d) -> f a c -> f b d 

class Biapplicative m => Bimonad m where
  bibind :: m a b -> (a -> b -> m c d) -> m c d

  bireturn :: a -> b -> m a b
  bireturn = bipure

bilift :: Biapplicative f => (a -> b) -> (c -> d) -> f a c -> f b d
bilift f g = biap $ bipure f g 

bilift2 :: Biapplicative f => (a -> b -> c) -> (x -> y -> z) -> f a x -> f b y -> f c z
bilift2 f g = biap . biap (bipure f g)

Pair 是这些的一个实例：

instance Bifunctor (,) where
  bimap f g (x,y) = (f x, g y)

instance Biapplicative (,) where
  bipure x y = (x,y)
  biap (f,g) (x,y) = (f x, g y)

instance Bimonad (,) where
  bibind (x,y) f = f x y

类型如...

data Maybe2 a b = Fst a | Snd b | None
--or 
data Or a b = Both a b | This a | That b | Nope

...IMO 也会有实例。

没有足够的匹配类型吗？还是我的代码存在严重缺陷？

Answer 1

范畴论中的单子是一个内函子，即域和余域是同一类别的函子。但是Bifunctor 是从产品类别Hask x Hask 到Hask 的函子。但我们可以尝试找出 Hask x Hask 类别中的 monad 是什么样的。它是一个类别，其中对象是成对的类型，即(a, b)，箭头是成对的函数，即从(a, b) 到(c, d) 的箭头具有(a -> c, b -> d) 类型。此类别中的内函子将类型对映射到类型对，即(a, b) 到 (l a b, r a b)，并将箭头对映射到箭头对，即

(a -> c, b -> d) -> (l a b -> l c d, r a b -> r c d)

如果将此映射函数拆分为 2，您将看到 Hask x Hask 中的一个内函子与两个 Bifunctors、l 和 r 相同。

现在是 monad：return 和 join 是箭头，所以在这种情况下，它们都是 2 个函数。 return 是从(a, b) 到(l a b, r a b) 的箭头，join 是从(l (l a b) (r a b), r (l a b) (r a b)) 到(l a b, r a b) 的箭头。这是它的样子：

class (Bifunctor l, Bifunctor r) => Bimonad l r where
  bireturn :: (a -> l a b, b -> r a b)
  bijoin :: (l (l a b) (r a b) -> l a b, r (l a b) (r a b) -> r a b)

或分离出来：

class (Bifunctor l, Bifunctor r) => Bimonad l r where
  bireturnl :: a -> l a b
  bireturnr :: b -> r a b
  bijoinl :: l (l a b) (r a b) -> l a b
  bijoinr :: r (l a b) (r a b) -> r a b

和m >>= f = join (fmap f m)类似，我们可以定义：

  bibindl :: l a b -> (a -> l c d) -> (b -> r c d) -> l c d
  bibindl lab l r = bijoinl (bimap l r lab)
  bibindr :: r a b -> (a -> l c d) -> (b -> r c d) -> r c d
  bibindr rab l r = bijoinr (bimap l r rab)

相对单子

最近开发了relative monads。相对单子不需要是内函子！如果我们将论文翻译成 Haskell 中的Bifunctors，您会得到：

class RelativeBimonad j m where
  bireturn :: j a b -> m a b
  bibind :: m a b -> (j a b -> m c d) -> m c d

它定义了一个相对于双函子j 的单子。如果您选择 j 为 (,)，您将得到您的定义。

定律与单子定律相同：

bireturn jab `bibind` k = k jab
m `bibind` bireturn = m
m `bibind` (\jab -> k jab `bibind` h) = (m `bibind` k) `bibind` h

第一定律阻止Maybe2 成为实例，因为bibind 必须能够从bireturn 的结果中提取两个值。