Haxe 自定义元数据到宏调用

Question

假设我创建了一个可以像这样使用的构建宏

@:build(macros.SampleMacro.build("arg"))
class Main {}

是否可以将其转换为自定义的速记元数据？

@:samplemacro("arg")
class Main {}

有这方面的文档吗？

Answer 1

我不确定这是否可行，但您可以利用 @:autoBuild() 元数据适用于接口的事实。这通常用于像这样的“标记接口”：

class Main implements ISampleMacro {}

@:autoBuild(macros.SampleMacro.build("arg"))
interface ISampleMacro {}

但是，您可能希望每次使用时都使用不同的"arg"，而不是对其进行硬编码。您可以通过使用@:const 类型参数来实现这一点：

class Main implements ISampleMacro<"foo"> {}

@:autoBuild(macros.SampleMacro.build())
interface ISampleMacro<@:const T> {}

在构建宏中提取类型参数的值比简单地向其传递参数需要更多的努力：

switch (Context.getLocalClass().get().interfaces[0].params[0]) {
    case TInst(_.get() => t, params):
        switch (t.kind) {
            case KExpr({expr: EConst(CString(arg)), pos: _}):
                trace(arg); // "foo"
            case _:
        }
    case _:
}

Answer 2

经过一番磕磕绊绊，我发现这是可以做到的。

部分解决方案是使用

--macro addGlobalMetadata('$path', '@:build(Build.build())')

这使您可以将@:build 函数分配给$path 中的所有类。这可以用作编译器选项或 haxeflag。

但仅靠这还不足以采用采用动态参数的元数据标签。但是因为我们现在有一个为我们所有的类执行的 Build.build()，那个 Build.build() 函数都可以处理检查哪些类有我们的自定义元数据标记，以及为我们可能需要的那些类构建任何东西。

为了检查我们的自定义元数据标签，我们将检查宏设置如下：

class Build {

    static var META_STR:String = ":samplemacro";

    macro static public function build():Array<Field> {

        // We check only those Contexts for where a class type exists
        var localClass:Null<Ref<ClassType>> = Context.getLocalClass();
        if(localClass == null) return null; // no class type

        // We check if the metadata for the class contains our 
        // custom metadata string at all
        if(!localClass.get().meta.has(META_STR)) return null;

        // This class does have our custom metadata!
        // Because there may be more than one of the same type
        // of metadata, we extract a list of all the custom metadata tags

        var customTags = localClass.get().meta.extract(META_STR);

        // For each tag we can get at the arguments passed in 
        // by accessing the params field
        for(customTag in customTags){
            var params = customTag.params;

            // Here we can handle each of our @:samplemacro(params) tags,
            // save the params for use later, or 
            // pass the arguments over to another class to deal with
        }

        var fields = Context.getBuildFields();

        // Modify the class fields the way you want

        // Optionally destroy the metadata tags afterwards
        // with localClass.get().meta.remove(META_STR);

        return fields;
    }
}

有关 addGlobalMetadata 的更多详细信息，请访问： https://stackoverflow.com/a/38075492/1502818