Haxe 宏将 null 设置为调用实例？

Question

由于某些“宏函数调用”，有没有办法将null 设置为调用实例？

像这样：

class A {
    // ...
    macro function DestroyItself() {
        // ...
    }
}

var a:A = new A();
// ...
a.DestroyItself();
trace(a); // "null"

Answer 1

是的：

macro public function destroy(self:Expr) {
    return macro $self = null;
}
// ...
a.destroy();

在非静态宏函数中，第一个 Expr 参数是调用者实例的引用。

Answer 2

曾经的方法是为null 任何实例创建通用工具。

package ;

class Tools
{
    /**
     *  Simply assigns null to the instance
     *  See more at: http://code.haxe.org/category/macros/generating-code-in-a-macro.html
     *  
     *  @param instance - Any
     *  @return haxe.macro.Expr
     */
    public static macro function nullMe(instance : haxe.macro.Expr.ExprOf<Dynamic>) : haxe.macro.Expr
    {
        return macro {
            ${instance} = null;
        };
    }
}

这使用using Tools; 来一般null 任何实例，但我会不推荐这个。我会使用每类方法。

Main.hx

package ;

class Main {

    static function main() {
        // Construct
        var instance = new SomeClass();

        // Destroy
        instance.destroy();

        // Trace null
        trace(instance);
    }
}

SomeClass.hx

package ;

class SomeClass
{
    public function new()
    {
        trace("Hello from SomeClass!");
    }

    private function preDestroy()
    {
        trace("The end is nigh!");
    }

    public macro function destroy(self : haxe.macro.Expr) : haxe.macro.Expr
    {
        return macro {
            @:privateAccess ${self}.preDestroy();
            ${self} = null;
        };
    }
}

编译好的 JS

// Generated by Haxe 3.4.2
(function () { "use strict";
var Main = function() { };
Main.main = function() {
    var instance = new SomeClass();
    instance.preDestroy();
    instance = null;
    console.log(instance);
};
var SomeClass = function() {
    console.log("Hello from SomeClass!");
};
SomeClass.prototype = {
    preDestroy: function() {
        console.log("The end is nigh!");
    }
};
Main.main();
})();