带有 C 的汇编程序 - 分段错误

Question

我有两个文件：f1.S 用汇编语言编写的斐波那契函数（计算斐波那契数列的第 n 个成员）在哪里，以及调用斐波那契函数的 f2.c。

以下是这些文件： f1.S

.global fibonacci
fibonacci:

push %rbp
movq %rsp, %rbp
push %rax

movq 16(%rbp), %rax 

cmp $0, %rax
je zeroValue
cmp $1, %rax
je oneValue
jmp more

zeroValue:
addq $0, %r8
jmp end

oneValue:
addq $1, %r8
jmp end

more:
movq 16(%rbp), %rax
dec %rax
pushq %rax
call fibonacci
movq 16(%rbp), %rax
dec %rax
dec %rax
pushq %rax
call fibonacci

end:
mov %rbp, %rsp
pop %rbp
ret

f2.c

#include <stdio.h>
extern int fibonacci (int);
int main ()
{
    int n = 6;
    int res;
    res = fibonacci(n);
    printf ("N-th member of Fibonacci sequence is: %d", res);
    return 0;
}

为了编译和链接，我正在执行以下命令：

as f1.S -o f1.o

gcc f2.c -c -o f2.o

gcc f2.o f1.o -o program

在我尝试运行我的 exe 文件（程序）之前一切正常。我无法运行它，因为我收到消息：分段错误。我究竟做错了什么？ 斐波那契函数肯定没问题，因为我在干净的汇编器中使用它，然后它就起作用了。

Answer 1

在 gdb 中你会得到这样的 SIGSEGV：

Program received signal SIGSEGV, Segmentation fault.
fibonacci () at f1.S:6
6   push %rax

更有趣的是你的回溯（结束）：

(gdb) backtrace -10
#1048280 0x00007fffffffe6e0 in ?? ()
#1048281 0x000000000040056d in more () at f1.S:28
#1048282 0x00007fffffffe7fe in ?? ()
#1048283 0x00007fffffffe7ff in ?? ()
#1048284 0x00007fffffffe700 in ?? ()
#1048285 0x000000000040056d in more () at f1.S:28
#1048286 0x00007fffffffe7ff in ?? ()
#1048287 0x0000000000000006 in ?? ()
#1048288 0x00007fffffffe720 in ?? ()
#1048289 0x000000000040051f in main () at f2.c:7
Backtrace stopped: previous frame inner to this frame (corrupt stack?)

所以你设法调用你的递归 1 048 289 次......

此外，在第 8 行 (movq 16(%rbp), %rax) 之后，您将获得：

(gdb) i r rax
rax            0x7fffffffe800   140737488349184

从你的函数来看，rax 应该是一个计数器。

由于您使用的是 64 位寄存器，我假设您正在运行 x86_64 架构 which doesn't store arguments on stack 但使用注册表：

如果类是 INTEGER，则使用序列 %rdi、%rsi、%rdx、%rcx、%r8 和 %r9 的下一个可用寄存器

(gdb) i r edi
edi            0x6  6

您的解决方案可能在 cdecl calling convention 上运行良好，但在 Microsoft x64 调用约定 或 System V AMD64 ABI 上运行良好。

例如，完成此操作的一种方法是（适用于 System V AMD64 ABI）：

.global fibonacci
fibonacci:

push %rbp
push %rdi

cmp $0, %rdi
je zeroValue
cmp $1, %rdi
je oneValue
jmp more

zeroValue:
    movq $0, %rax
    jmp end

oneValue:
    movq $1, %rax
    jmp end

more:
    dec %rdi
    call fibonacci
    push %rax
    dec %rdi
    call fibonacci
    pop %r8
    add %r8, %rax

end:
    pop %rdi
    pop %rbp
    ret

如下：

• 存储 rbp
• 存储 rdi
• 如果 rdi == 0：返回 0
• 如果 rdi == 1：返回 1
• 降低rdi
• 调用斐波那契
• 将结果存储在堆栈中
• 降低rdi
• 调用斐波那契
• 将结果恢复到 r8
• 将 r8 添加到结果中
• 恢复 rdi
• 恢复 rbp

出于好奇，这里有一个没有递归的版本，只有一个循环（很少有处理低值的情况）：

.global fibonacci
fibonacci:

cmp $2, %rdi # 2 and higher should be computer normally
jg compute

cmp $0, %rdi
jz zero 
mov $1, %rax # 1st and 2nd elements = 1
ret

zero:
    mov $0, %rax
    ret

compute:
    mov %rdi, %rcx  # Use cpu counter register
    sub $2, %rcx    # The first number that will come out of this loop
                    # is 2, so decrease number of iterations
    mov $1, %r8     # a = 1
    mov $1, %r9     # b = 1

begin_iter:
    mov %r9, %rax   # sum = b
    add %r8, %rax   # sum += a
    mov %r9, %r8    # a = b
    mov %rax, %r9   # b = a

    loop begin_iter

    ret

Answer 2

首先，确定 C 函数将如何调用您的汇编函数。所以你可以准备你的汇编函数来处理调用。

例如如果c调用在汇编函数返回stdcal后不会清理堆栈，那么你必须在汇编代码中清理堆栈

编辑：删除了有关寄存器语法的通知。谢谢维克托