将 n 位二进制转换为以 10 为底的数字答案

【问题标题】：Convert n-bit binary to base 10 number将 n 位二进制转换为以 10 为底的数字
【发布时间】：2021-04-07 18:26:56
【问题描述】：

我在看这个小人电脑问题：

第一个输入确定 n 的值，假设该值等于或大于 4
示例：如果第一个输入是八 (8)，则请求八个后续输入。如果随后的输入编号为 1、0、0、1、0、0、0、0，则输出将为 9。
n 个输入值由用户提供，每个位一个：第一个是最低有效位。第 n 个输入是最重要的位。

我的尝试：

IN
STO NUMBER
IN
STO A
IN
STO B
IN
STO C
IN
STO D


LOOPB: LDA FOUR
BRZ ENDB
SUB ONE
STO FOUR
LDA RESB
ADD B
STO RESB
BRP LOOP
ENDB:LDA RESB
OUT
HLT

ONE: DAT 1
EIGHT: DAT 8
FOUR: DAT 4
TWO: DAT 2
POWERONE: DAT 1

RESA: DAT 000
RESB: DAT 000

RESULT: DAT 000

NUMBER: DAT 0
A: DAT 0
B: DAT 0
C: DAT 0
D: DAT 0

我不知道如何解决这个问题，如何使 00001001 在 LMC 上转换为 9？我不确定如何在 LMC 上进行乘法运算。

【问题讨论】：

n在这个算法中的作用是什么？这是接下来的输入数量吗？每个下一个输入是单个二进制数字吗？ NUMBER 在您的代码中的用途是什么，因为您在输入后从不使用它？
您的代码中EIGHT、TWO、POWERONE 和RESA 的用途是什么...它们从未被使用过？ |A 是什么意思？是评论吗？
n 的作用是请求后续输入，比如 n 是 8，后续输入为 1,0,0,1,0,0,0,0 则输出为 9，其中第一个是最不重要的，第 n 个输入是最重要的。八的目的是我确实知道如何在LMC中进行乘法运算，所以我只是直接输出结果。 A 是评论
你可以通过将一个数字添加到自身来乘以 2（这个问题所需要的全部）。
是的！非常感谢您的帮助！！

标签： little-man-computer

【解决方案1】：

您拥有的代码不使用第一个输入。相反，它使用FOUR。这是要更改的第一件事，因为您不希望恰好循环四次，而是与您的第一个输入一样多。

其次，您不需要将每个下一个输入存储在单独的邮箱中。相反，您可以立即处理 0/1 输入，因为它决定是否要向结果中添加某些内容。所以你只需要根据输入的 0/1 值更新结果。你不需要自己存储那个 0/1 值——所以不需要A、B、C...等。而是将IN 指令放在循环中。

然后仍然是what，当输入结果为 1 时，您应该添加到结果中。由于输入是相反的顺序（最低有效位在前），您应该跟踪2 的幂，在循环的每次迭代中将其翻倍。每当您遇到输入 1 时，这将是添加到结果中的数字。因为这就是二进制系统的工作方式。比如输入的数字是1 1 0 1，那么计算是：

input digit	power of 2	to be added	running sum
1	1	yes	1
1	2	yes	3
0	4	no	3
1	8	yes	11

所以这是脚本。你可以在这里运行它：首先运行代码 sn-p（它启动 LMC 模拟器），然后使用右侧面板中的控件：

#input:8 1 0 1 1 0 0 0 0
       LDA ZERO   # Initialise, so program still runs 
       STO RESULT #   correctly when it is reset.
       LDA ONE
       STO POWER
       IN         # Get number of binary digits
LOOP   BRZ OUTPUT # All digits have been read
       STO COUNT
       IN         # Get a binary digit
       BRZ NEXT   # Nothing to add when it's zero
       LDA RESULT # Add a power of 2 to the result
       ADD POWER
       STO RESULT
NEXT   LDA POWER  # Next power of 2
       ADD POWER
       STO POWER
       LDA COUNT  # Prepare for next iteration
       SUB ONE
       BR  LOOP

OUTPUT LDA RESULT
       OUT
ZERO   HLT
ONE    DAT 1
POWER  DAT 1
COUNT  DAT
RESULT DAT



<script src="https://cdn.jsdelivr.net/gh/trincot/lmc@v0.816/lmc.js"></script>

【讨论】：