用每个子字符串替换来替换多个子字符串

Question

关于以下字符串：“狗吃猫，还是你的猫吃老鼠？”

我想在 Perl 中使用 s/// 将每次出现的“dog”替换为“cat”，将“cat”替换为“mouse”，将“mouse”替换为“dog” ”。

所以结果是：“猫吃老鼠，还是你的老鼠吃狗？”

我的问题是，用猫替换狗后，猫出现了两次，但我只想替换原来的猫。

我知道我可以简单地编写几个非全局替换，但我想知道是否有一个单行符。

ps：当然我想使用正确的复数形式，例如“mice”而不是“mouses”

Answer 1

您可以使用正则表达式查找所有匹配项，并使用哈希查找替换项。
下面请找到从哈希保持匹配=>替换映射的键构造正则表达式的脚本。

简单的“概念证明”版本：

%S=(dog=>'cat',cat=>'mouse'); # hash with match=>replacements mappings
# substitute "dog" and "cat" for values provided by S hash
s/\b(dog|cat)\b/$S{$1}/g;
# OR if if can easily split input string into "words"
#    substitute "words" present in S hash and keep the rest unchanged
s{\b(\S+?)\b}{$S{$1}//$1}g;

从哈希键和测试构造正则表达式的详细版本：

#!/usr/bin/perl
use strict;
use warnings;

# %S - hash keeping match=>replacements pairs
my %S = (
  dog  => "cat",
  dogs => "cats",
  cat  => "mouse",
  cats => "mice",
  mouse => "dog",
  mice  => "dogs",
);
my $regex = sprintf '\b(?:%s)\b', join('|',sort keys %S);
$regex = qr($regex);
print "REGEX: ",$regex,"\n"; # print regexp for finding all matches

while( <DATA> ) {
  print "IN:  ",$_; # print string before rewriting
  s/($regex)/$S{$1}/g; # Replace all matches by replacements provided by %S hash
  print "OUT: ",$_; # print string after rewriting
}

# Put your tests strings in lines below __DATA__
__DATA__
Do dogs eat cats, or does your cat eat a mouse?
Does firecat fly?