将子程序传递给 Perl 子程序

Question

我正在尝试制作一个模仿 Perl6/Raku 的 dir 的子程序。 dir 可以非常方便快捷地搜索目录，在目录中进行文件测试。

我正在尝试向dir 添加递归选项。

我有一个可以完成此任务的脚本，但我正在尝试使用我已经知道有效的 File::Find 脚本添加一个递归选项：

use File::Find;
my @files;
find({ wanted => \&process_file, no_chdir => 1 }, '.');
sub process_file {
    if ((-f $_) && ($_ =~ m/\.pl$/)) {#various tests on the files
            push @files, $_;
#        print "This is a file: $_\n";
    }
}

但是，我想在一个子程序中完成所有事情。

我试过这个：

use strict;
use warnings FATAL => 'all';
use feature 'say';
use autodie ':all';
use Carp 'confess';
use File::Find 'find';

sub dir { # a Perl5 mimic of Perl6/Raku's "dir"
    my %args = ( # default arguments listed below
        tests => 'f', dir => '.', regex   => '.', recursive => 0,
    @_, # argument pair list goes here
    );
    if ($args{tests} =~ m/[^rwxoRWXOezfdlpSbctugkTB]/){# sMAC returns are non-boolean, and are excluded
        confess "There are some unrecognized characters in $args{tests}";
    }
    my @items = split '', $args{tests};
    my $tests = '-' . join (' -', @items);
    undef @items;
    $args{regex} = qr/$args{regex}/;
    opendir my $dh, $args{dir} or die "Can't opendir on $args{dir}: $!";
    while (my $item = readdir $dh) {
        if (($item !~ $args{regex}) or ($item =~ m/^\.{1,2}$/)) { next  }
        my $i = "$args{dir}/$item";
        if (not defined $i) {
            confess "\$i isn't defined.";
        }
        my $rv = eval "${tests} \$i" || 0;
        if ($rv == 0) { next }
        if ($args{dir} eq '.') {
            push @items, $item
        } else {
            push @items, $i
        }
    }
# this is the new part, and what doesn't work
    if ($args{recursive} == 1) {
        find({
            wanted => \sub {
                if ((eval "${tests} $_") && ($_ =~ /$args{regex}/)) {
                    push @items, $_;
                }
            },
            chdir => 1,
            '.'
        });
    }
    @items
}
foreach my $pl (dir(recursive => 1, regex => '\.pl$')) {
    say $pl
}

这给出了一个错误：

Odd number of elements in anonymous hash at clean.pl line 44

我认为这是因为底部的find 函数，如错误所示。

Passing one subroutine to another subroutine 与我的问题有些相似，但我不知道如何将其应用于我的案例。

传递wanted => sub 和wanted => \sub 会产生同样的错误。

我怎样才能让这个wanted 子例程无错误地传递给find？

Answer 1

Perl 尝试使用每个奇数参数作为散列键，每个偶数作为散列值，所以如果使用奇数个参数，你会得到“奇数个参数”错误，因为你把所有参数都放到 find 匿名哈希参考。文件名/路径没有哈希键，所以把它移出 hashref。

然后像这样传递wanted 例程：

wanted => sub { ... }

也就是说，我的 File::Find 只知道no_chdir，而不知道chdir，所以你可能想要切换值。

这对我有用：

find(
    {
        wanted => sub {
            if ((eval "${tests} $_") && ($_ =~ /$args{regex}/)) {
                push @items, $_;
            }
        },
        no_chdir => 0,
    },
    '.'    # File outside the hash ref
);