将哈希传递给子程序

Question

我正在为自己开发一个项目，但在将哈希传递给子例程时遇到了问题。实际上有几个子例程，但我试图将其精简到最低限度。我意识到 %mdc 是一个全局哈希，所以我不必将它传递给我拥有的所有子例程，但出于习惯，我更喜欢这种方式。虽然下面的 sn-p 确实有效，但感觉它可以更清洁。

不管怎样，让我想到一定有更好的方法的部分是以下几行：

%mdc_def = mysub(\%mdc);
%mdc = %$mdc_def;

感觉...对我来说很笨拙，但我没有找到一种方法让这两行只是一个...类似于（即使它的语法不好）：

%mdc = %mysub(\%mdc);

然后，如果我应该有一个 mysub2 也需要该哈希，那么我也必须在该子例程中执行相同的两行随机播放。只是感觉很乱。

这是我正在处理的 sn-p：

use strict;
use warnings;

my %mdc = ();
my $mdc_def;

$mdc{abc} = 123;
$mdc{cde} = 234;

foreach (sort keys (%mdc)) { print "before $_ = $mdc{$_}\n"; }
$mdc_def = mysub(\%mdc);
%mdc = %$mdc_def;
foreach (sort keys (%mdc)) { print " after $_ = $mdc{$_}\n"; }

sub mysub {
  my ($mdc_def) = @_;
  my %m = %$mdc_def;

  $m{def} = 345;
  $m{efg} = 456; 

  return \%m;
}

提前致谢。

Answer 1

您可以使用以下内容：

sub mysub {
   my ($mdc_def) = @_;
   my %m = %$mdc_def;

   $m{def} = 345;
   $m{efg} = 456; 

   return \%m;
}

my %mdc = ( a=>1, b=>2 );

%mdc = %{ mysub(\%mdc) };

但这不会产生散列和其中所有标量的一个两个副本。全局 var 没有理由成为散列而不是标量，这样可以避免复制实例之一。

sub mysub {
   my ($mdc_def) = @_;
   my %m = %$mdc_def;

   $m{def} = 345;
   $m{efg} = 456; 

   return \%m;
}

my $mdc = { a=>1, b=>2 };

$mdc = mysub(\%mdc);

剩下一个复制实例。如果您不希望 mysub 就地修改哈希值，则需要该实例，因此上面的代码很好。

以下版本会就地修改哈希，避免第二次复制（并允许我们将全局变量保留为哈希）。

sub mysub_inplace {
   my ($mdc_def) = @_;
   $mdc_def->{def} = 345;
   $mdc_def->{efg} = 456; 
}

my %mdc = ( a=>1, b=>2 );

mysub_inplace(\%mdc);

Answer 2

试试

%mdc = %{mysub(\%mdc)};

• \%mdc 将对%mdc 哈希的引用作为参数传递给mysub suroutine
• %{ mysub(…)} 会将mysub 调用的返回值视为哈希引用并将其转换为哈希

您可以使用子程序原型sub mysub (\%) 调用mysub 和mysub(%mdc)

---

简单的工作示例/脚本：

#!/usr/bin/perl
# Original version constained prototypes for sub mysub - 
# see ikegami comments below the answear
use strict;
use warnings;

sub mysub {
  my( $hRef ) = (@_);
  $hRef->{a} = 0;
  $hRef->{c} = 3;
  return $hRef;
}

my %mdc = ( a=>1, b=>2);

%mdc = %{mysub(\%mdc)};
print %mdc;

Answer 3

您了解$hash_ref = \%hash 是什么以及如何使用它吗？

use strict;
use warnings;
use feature 'say';

my %mdc = ();

$mdc{abc} = 123;
$mdc{cde} = 234;

say '- Before ------------';

while( my($k,$v) = each %mdc ) {
    say "$k => $v";
}

mysub(\%mdc);

say '- After -------------';

while( my($k,$v) = each %mdc ) {
    say "$k => $v";
}

sub mysub {
  my $mdc_ref = shift;

  $mdc_ref->{def} = 345;
  $mdc_ref->{efg} = 456; 
}

输出

- Before ------------
cde => 234
abc => 123
- After -------------
def => 345
cde => 234
abc => 123
efg => 456