在循环Perl中删除数组中的元素

Question

我想创建一个循环，遍历一个数组 (@array1) 中的所有元素，如果在另一个数组 (@array2) 中找到相同的元素，我想要第三个数组 (@array3) 中的值) 将相同的索引添加到第一个数组并从第三个数组中删除。我尝试过这种方式，但是带有 if 语句的行在未初始化的值上运行，并且它永远循环。

    foreach my $elem1 (@array1){
        my $i = 0;
        while ($i < scalar @array2){
            if($array2[$i]==$elem1){
                push (@array1, $array3[$i]);
                delete $array2[$i];
            }
            else{
                $i++;
            }
        }
    }

Answer 1

问题是如果元素匹配，你不会增加 $i。删除else。

Answer 2

嗯，这是处理问题的一种方法（在我理解您想要做什么的范围内）。每当您需要回答有关成员资格的问题时，您可能需要使用哈希。

use strict;
use warnings;

my @array1 = ( 11, 22, 33,  44);
my @array2 = ( 11,  2,  3,  44,  5,   44);
my @array3 = (-11, -2, -3, -44, -5, -444);

# Keep track of every value in @array1.
my %vals = map { $_ => 1 } @array1;

my @keep_indexes;

# Go through @array2, either adding the corresponding
# value in @array3 to @array1 or storing the array index.
for my $i (0 .. $#array2) {
    if ($vals{$array2[$i]}){
        push @array1, $array3[$i];
    }
    else {
        push @keep_indexes, $i;
    }
}

# Rebuild @array3 from the indexes that we stored.
# Change this to @array2 if you want to delete from that array instead.
@array3 = map $array3[$_], @keep_indexes;

print join(' ', @array1), "\n"; # 11 22 33 44 -11 -44 -444
print join(' ', @array2), "\n"; # 11 2 3 44 5 44
print join(' ', @array3), "\n"; # -2 -3 -5

我不喜欢那个代码，所以这里有一些警告：

• 任何时候你给变量名编号（@array1、@array2 等），你都会陷入混乱。您需要更好的变量名称，或者更有可能的是更好的数据结构。
• 每当您发现自己从事维护并行数组的业务时，都应该考虑更好的数据结构是否会有所帮助。

Answer 3

您正在从 array2 中删除一个元素，而不是问题中所述的 array3。我认为删除操作将数组元素设置为undef。下一次循环时，它会检查与 $elem 相同的元素，现在是 undef。因此错误。然后他一次又一次地做同样的事情。