Perl从数组中删除元素答案

【问题标题】：Perl Deleting element from arrayPerl从数组中删除元素
【发布时间】：2013-04-16 12:16:18
【问题描述】：

我在 perl 中有一个二维数组。我想删除所有具有 >> 模式的元素。我写了一个 perl 代码，在匹配模式之前它工作得很好，但是它不能删除那个元素，会发生一些错误。

 foreach my $x(@array)
   { 
     foreach my $y(@$x)
     {
        if($y =~ (m/^(\<+)|(\>+)$/ig))
         {
            delete $y;
         }
     }
   }

你能帮我删除与模式匹配的特定元素吗？（我想从数组中删除和移除，而不是取消定义）

【问题讨论】：

您没有收到错误delete argument is not a HASH or ARRAY element 吗？如果你这样做了，为什么你没有在你的问题中说这个？
引用perldoc.perl.org/functions/delete.html -- WARNING: Calling delete on array values is deprecated and likely to be removed in a future version of Perl.
一个更好的问题是，您能否在将<<< 值存储到二维数组中之前删除它们？
您的正则表达式不需要/g 或/i。您也不需要捕获组。可以简化为m/^<|>$/。
除非你真正想要的是/^(?:<+|>+)$/。

标签： regex perl

【解决方案1】：

假设您的数组如下所示：

1  2  3  4
5  X  6  7
8  9  A  B

您想删除X。你想发生什么？删除后你的新数组应该是什么样子？

你想要这个吗：

1  2  3  4
4  6  7
8  9  A  B

还是这个？

1  2  3  4
5  9  6  7
8     A  B

这是您需要决定的第一件事。其次，你不能使用delete。 delete 命令从 hash 而不是 array 中删除键控值。如果你有这样的数组：

my @array = qw(0 1 2 3 4 5 X 7 8 9);

如果您想删除X（即$array[6]），您可以使用splice 命令：

splice @array, 6, 1;

最后，Perl 没有二维数组，所以你不能从二维数组中删除一个值。

你所拥有的是第二个数组的 references 数组。这样想：

my @row0 = qw(1 2 3 4);
my @row1 = qw(5 X 6 7);
my @row2 = qw(8 9 A B);

my @two_d_array = (\@row0, \@row1, \@row2);

或者，我可以按列执行此操作：

my @col0 = qw(1 5 8);
my @col1 = qw(2 X 6);
my @col2 = qw(2 6 A);
my @col3 = qw(4 7 B);

my @two_d_array = (\@col0, \@col1, \@col2, \@col3);

当你谈论时。

if ( $two_d_array[1][1]` eq "X" ) {

发生的事情是 Perl 扰乱了你的思维。它让您认为涉及到一个二维数组，但实际上并非如此。

更准确的写法是：

if ( ${ $two_d_array[1] }[1] eq "X" ) {

或者，更简洁：

if ( $two_d_array[1]->[1] eq "X" ) {

所以首先，确定你的意思是删除一个值。在二维数组中，如果您真的删除该值，最终会破坏该数组的维度结构。也许您可以替换那个时候的值undef。

一旦你这样做了，你必须明白你实际处理的是什么：一个数组的references数组。

for my $array_reference ( @two_d_array ) {
    for my $value ( @{ $array_reference } ) {
        if ( $value =~ /^(<+|>+)$/ ) {
            $value = undef;   #See Note #1
        }
    }
}

注意 #1：当您使用 for 循环时，数组的索引是指向数组中实际值的链接。因此，当您更改索引时，您正在更改实际值。这就是为什么这会起作用。

如果您真的非常想使用splice 删除元素，您必须决定是向上移动元素以替换已删除的值还是向左移动以替换已删除的值。如果要将值向左移动，则需要一个数组或对行数组的引用。如果您希望将值向上移动以填充已删除的值，则需要一个对列数组的引用数组。

请记住，计算机将完全按照您的指示执行操作，而不是您希望它们执行的操作。确保您完全了解自己想要什么。

【讨论】：

【解决方案2】：

您正在对标量值$y 应用delete，而delete 仅适用于散列和数组。你需要做的事

for my $x (0 .. $#array) {
    for my $y (0 .. $#{$array[$x]}) {
        if (...) { delete $array[$x][$y]; }

在我看来，最好的解决方案是在将值存储到数组之前删除它。我猜您是从某个数据源（例如文件）中读取它的，那将是过滤掉它的最佳位置。例如

while (<$fh>) {
    ....
    @values = grep !/^[<>]+/, @values;    # filtering
    push @array, \@values;                # storing
}

在此说明中，您也可以事后也这样做，当然，使用类似的方法：

for (@array) {
    @$_ = grep !/^[<>]+/, @$_;
}

【讨论】：

您的第一个代码 sn-p 符合我的要求，但是它给出了 undef 值。我想从我的数组中完全删除元素。
@SomnathPaul 我鼓励您更仔细地阅读我的回答。您提到的“代码 sn-p”不是我推荐的解决方案。但是，只有在您阅读了我写的内容后，才能将这些信息转发给您，并且这已经写在我的答案中。
@SomnathPaul 见我的answer。您不能在不影响该数组结构的情况下删除二维数组中的值。

【解决方案3】：

您可以通过拼接函数从数组中删除元素： splice(@array, $index, 1); 这个例子中的 1 是元素个数，你要删除
delete 函数只设置数组值为 undef

【讨论】：

但是我需要删除当前由 $y 表示的元素。我们如何做到这一点？
使用for函数浏览数组：for my $y(0..$#array) {} $y 将是数组中元素的个数

【解决方案4】：

delete 不会改变数组索引，所以它不是你想要的。如果要按值删除元素，请使用以下内容：

foreach my $x(@array)
   {   
       $x = [ grep { $_ !~ (m/^(\<+)|(\>+)$/ig)} @$x ];
       print join(",", @$x), "\n";
   }

或者，使用拼接。但是你需要使用索引而不是值来迭代数组。

另见Perl-delete、Perl-splice。

【讨论】：