用 foldr 构建平衡二叉树

Question

我编写了函数foldTree 从列表中构建平衡二叉树。 我必须使用foldr，没关系，我使用了它，但我使insertInTree函数递归=（现在我只知道这种穿过树木的方式=））。

更新：我不确定函数insertTree：递归计算高度是否正确？ =((这里需要一些帮助。

是否可以在没有递归的情况下编写insertInTree（带有until/iterate/unfoldr 的东西）或者在没有辅助函数的情况下使foldTree 函数=> 以某种方式更短？

这是我的尝试：

data Tree a = Leaf
            | Node Integer (Tree a) a (Tree a)
            deriving (Show, Eq)

foldTree :: [a] -> Tree a
foldTree = foldr (\x tree -> insertInTree x tree) Leaf

insertInTree :: a -> Tree a -> Tree a
insertInTree x Leaf = Node 0 (Leaf) x (Leaf)
insertInTree x (Node n t1 val t2) = if h1 < h2 
                                    then Node (h2+1) (insertInTree x t1) val t2 
                                    else Node (h1+1) t1 val (insertInTree x t2) 
  where h1 = heightTree t1
        h2 = heightTree t2

heightTree :: Tree a -> Integer
heightTree Leaf = 0
heightTree (Node n t1 val t2) = n

输出：

*Main> foldTree "ABCDEFGHIJ"
Node 3 (Node 2 (Node 0 Leaf 'B' Leaf) 'G' (Node 1 Leaf 'F' (Node 0 Leaf 'C' Leaf))) 'J' (Node 2 (Node 1 Leaf 'D' (Node 0 Leaf 'A' Leaf)) 'I' (Node 1 Leaf 'H' (Node 0 Leaf 'E' Leaf)))
*Main> 

Answer 1

当两个子树的高度相等时，您的插入函数会出错，因为如果插入到正确的子树中，如果它已经满了，它的高度会增加。我不清楚您的代码中是否会出现这种情况。

将新元素插入树中的明显正确方法似乎是

insertInTree x (Node n t1 val t2) 
    | h1 < h2   = Node  n (insertInTree x t1) val t2 
    | h1 > h2   = Node  n    t1 val t2n 
    | otherwise = Node (h+1) t1 val t2n  
  where h1  = heightTree t1
        h2  = heightTree t2
        t2n = insertInTree x t2
        h   = heightTree t2n     -- might stay the same

这会创建几乎平衡的树（也称为 AVL 树）。但是它将每个新元素推到树的最底部。

编辑：这些树可以很好地看到

showTree Leaf = ""  
showTree n@(Node i _ _ _) = go i n
  where
  go _ (Leaf) = "" 
  go i (Node _ l c r) = go (i-1) l ++ 
    replicate (4*fromIntegral i) ' ' ++ show c ++ "\n" ++ go (i-1) r 

试试

putStr 。 showTree $ foldTree "ABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890"

是的，你可以把foldTree写得更短，就像

foldTree = foldr insertInTree Leaf

Answer 2

只想指出，接受的答案是好的，但在拥有高度为 3 的平衡二叉树后将不起作用，因为它没有考虑插入后左侧树的高度可能小于右侧的事实。

显然，代码可以添加一个额外的条件：

insertInTree x (Node n t1 val t2) 
    | h1 < h2   = Node  n      t1n val t2 
    | h1 > h2   = Node  n      t1  val t2n
    | nh1 < nh2 = Node  n      t1n val t2
    | otherwise = Node (nh2+1) t1  val t2n 
  where h1  = heightTree t1
        h2  = heightTree t2
        t1n = insertInTree x t1
        t2n = insertInTree x t2
        nh1 = heightTree t1n
        nh2 = heightTree t2n