Erlang中的list partition和splitwith有什么区别吗？

Question

就像标题一样。 lists:partition/2 和 lists:splitwith/2 都将函数谓词和一个列表作为输入，并生成一个包含两个列表的元组，其中一个谓词返回 true，另一个则谓词返回 false。

让我困惑的是最后一句话：

另请参阅（这里是另一个函数）以了解对列表进行分区的不同方式。

如果要给出相同的结果，他们肯定会写这两个函数以相同的方式而不是不同的方式划分列表吗？

Answer 1

我觉得源码很清楚。

partition(Pred, L) ->
    partition(Pred, L, [], []).

partition(Pred, [H | T], As, Bs) ->
    case Pred(H) of
    true -> partition(Pred, T, [H | As], Bs);
    false -> partition(Pred, T, As, [H | Bs])
    end;
partition(Pred, [], As, Bs) when is_function(Pred, 1) ->
    {reverse(As), reverse(Bs)}.

拆分/2：

splitwith(Pred, List) when is_function(Pred, 1) ->
    splitwith(Pred, List, []).

splitwith(Pred, [Hd|Tail], Taken) ->
    case Pred(Hd) of
    true -> splitwith(Pred, Tail, [Hd|Taken]);
    false -> {reverse(Taken), [Hd|Tail]}
    end;
splitwith(Pred, [], Taken) when is_function(Pred, 1) ->
    {reverse(Taken),[]}.

您可以看到splitwith/2 将在Pred 为false 时结束递归。

Answer 2

对于您的问题 - 是的，这些功能之间存在差异。现在解释一下：

如lists:splitwith/2 的文档中所述

根据Pred 将List 划分为两个列表。 splitwith/2 行为 好像是这样定义的：

splitwith(Pred, List) -> {takewhile(Pred, List), dropwhile(Pred, List)}.

这意味着Pred(Elem) 从List 的第一个元素开始运行。 而 Pred(Elem) 返回true，Elem 将被添加到第一个列表中。 一旦我们找到Pred(Elem) 返回false 的元素，List 中的其余元素将进入第二个列表。

相比之下，lists:partition/2 在List 的所有 元素上运行Pred(Elem)。如果它为特定元素返回true，它将进入第一个列表，如果它返回false，则该元素将进入第二个列表。它不会在返回 false 的第一个元素上“停止”，例如在 lists:splitwith/2 中。

让我们看一下除了文档中给出的两个之外的另一个简单示例：

1> List = [a,b,a,b].
[a,b,a,b]
2> Pred = fun(Elem) -> Elem =:= a end.
#Fun<erl_eval.6.54118792>
3> lists:partition(Pred,List).
{[a,a],[b,b]}
4> lists:splitwith(Pred,List).
{[a],[b,a,b]}

如我们所见，Pred 函数在Elem =:= a 时返回true。

如果我们运行lists:partition/2，它将遍历所有元素。所以我们在返回的元组的第一个列表中从List 中获取所有等于a 的元素，其余的在第二个列表中。

如果我们运行lists:splitwith/2，迭代会在到达Pred(Elem) 返回false 的第一个元素时“停止”。在这种情况下，它会停在第二个元素 b 上，并且从这个元素到列表末尾的所有元素都将转到返回元组的第二个列表。