在 F# 中旋转或压缩 seq<seq<'a>>

Question

假设我有一个序列序列，例如

{1, 2, 3}, {1, 2, 3}, {1, 2, 3}

什么是旋转或压缩这个序列的最佳方式，所以我有，

{1, 1, 1}, {2, 2, 2}, {3, 3, 3}

有没有一种可以理解的方法来做到这一点，而无需操纵底层的IEnumerator<_> 类型？

为了澄清，这些是seq<seq<int>> 对象。每个序列（内部和外部）可以有任意数量的项目。

Answer 1

这和@Asti的答案一样，只是稍微整理了一下：

[[1;2;3]; [1;2;3]; [1;2;3]] 
    |> Seq.collect Seq.indexed 
    |> Seq.groupBy fst 
    |> Seq.map (snd >> Seq.map snd);;

Answer 2

如果您要寻求语义 Seq 的解决方案，您将不得不一直保持懒惰。

let zip seq = seq
            |> Seq.collect(fun s -> s |> Seq.mapi(fun i e -> (i, e))) //wrap with index
            |> Seq.groupBy(fst) //group by index
            |> Seq.map(fun (i, s) -> s |> Seq.map snd) //unwrap

测试：

let seq =  Enumerable.Repeat((seq [1; 2; 3]), 3) //don't want to while(true) yield. bleh.
printfn "%A" (zip seq)

输出：

seq [seq [1; 1; 1]; seq [2; 2; 2]; seq [3; 3; 3]]

Answer 3

看起来像矩阵转置。

let data =
    seq [
        seq [1; 2; 3]
        seq [1; 2; 3]
        seq [1; 2; 3]
    ]

let rec transpose = function
    | (_::_)::_ as M -> List.map List.head M :: transpose (List.map List.tail M)
    | _ -> []

// I don't claim it is very elegant, but no doubt it is readable
let result =
    data
    |> List.ofSeq
    |> List.map List.ofSeq
    |> transpose
    |> Seq.ofList
    |> Seq.map Seq.ofList

或者，您可以对 seq 采用相同的方法，感谢 this answer 的优雅 Active 模式：

let (|SeqEmpty|SeqCons|) (xs: 'a seq) =
  if Seq.isEmpty xs then SeqEmpty
  else SeqCons(Seq.head xs, Seq.skip 1 xs)

let rec transposeSeq = function
    | SeqCons(SeqCons(_,_),_) as M ->
        Seq.append
            (Seq.singleton (Seq.map Seq.head M))
            (transposeSeq (Seq.map (Seq.skip 1) M))
    | _ -> Seq.empty

let resultSeq = data |> transposeSeq

另请参阅 this answer 了解技术细节和两个参考：PowerPack 的 Microsoft.FSharp.Math.Matrix 和涉及可变数据的另一种方法。

Answer 4

这看起来很不优雅，但它得到了正确的答案：

(seq [(1, 2, 3); (1, 2, 3); (1, 2, 3);]) 
|> Seq.fold (fun (sa,sb,sc) (a,b,c) ->a::sa,b::sb,c::sc) ([],[],[]) 
|> fun (a,b,c) -> a::b::c::[]