Clojure函数不返回地图

Question

我是 Clojure 和函数式编程的新手。我对 Clojure 中的数据结构（例如映射、列表和向量）有一个基本概念。

我正在尝试编写一个返回嵌套映射的函数。地图在函数内正确显示。下面的代码来自read-customer-file函数

([input-list new-map place-holder]
        (if (not-empty input-list)
            (do
                (def string-input (str (first input-list)))
                (def cust-id (get (first input-list) 0))
                (def cust-name (get (first input-list) 1))
                (def cust-address (get (first input-list) 2))
                (def cust-phone (get (first input-list) 3))
                (def temp-map (conj new-map {(keyword cust-id) {:cust-name cust-name, :cust-address cust-address, :cust-phone cust-phone}}))
                (read-customer-file (rest input-list) temp-map ())
            )
            (do 
                (map str new-map)
                ;(print (get-in new-map [:1 :cust-name]))
                (print new-map)
            )
        )
    )

这需要一个向量列表的输入，如下所示：

([3 Fan Yuhong 165 Happy Lane 345-4533] [2 Sue Jones 43 Rose Court Street 345-7867] [1 John Smith 123 Here Street 456-4567])

并返回一个嵌套映射如下：

{:3 {:cust-name Fan Yuhong, :cust-address 165 Happy Lane, :cust-phone 345-4533}, :2 {:cust-name Sue Jones, :cust-address 43 Rose Court Street, :cust-phone 345-7867}, :1 {:cust-name John Smith, :cust-address 123 Here Street, :cust-phone 456-4567}}

这是我正在努力实现的目标，并且在该功能中运行良好。但是，如果我尝试使用返回类型的值在函数外部定义一个变量，我不会得到一个嵌套映射，而是一个字符串列表。为此，我只删除了(print new-map) 部分。

(do 
    (map str new-map)
)

并从函数定义之外调用它，如下所示：

(def customer-info-list read-customer-file)
(println (customer-info-list))

得到的结果与我的预期不同，无法执行get和get-in等地图相关功能。

([:3 {:cust-name Fan Yuhong, :cust-address 165 Happy Lane, :cust-phone 345-4533}] [:2 {:cust-name Sue Jones, :cust-address 43 Rose Court Street, :cust-phone 345-7867}] [:1 {:cust-name John Smith, :cust-address 123 Here Street, :cust-phone 456-4567}])

我非常感谢任何形式的帮助。我知道我的代码有点乱，我应该使用let 而不是def 作为变量名。但我刚刚开始使用 Clojure，这是我的第一个程序。

更新

我解决了这个问题。我所做的是将地图更改为函数内的排序地图。所以函数的最后一个返回将是一个排序的映射。

(do 
    (into (sorted-map) new-map)
)

但是，如果分配给变量，返回的值仍然是一个字符串。所以我再次将其转换为排序映射。然后它最终被转换为嵌套地图。

(def customer-info-list read-customer-file)
(def cust-map (into (sorted-map) (customer-info-list)))
(println cust-map)
(println (get-in cust-map [:1 :cust-name]))
(println (get cust-map :2))

以上三个打印语句的输出与预期一致。

{:1 {:cust-name John Smith, :cust-address 123 Here Street, :cust-phone 456-4567}, :2 {:cust-name Sue Jones, :cust-address 43 Rose Court Street, :cust-phone 345-7867}, :3 {:cust-name Fan Yuhong, :cust-address 165 Happy Lane, :cust-phone 345-4533}}
John Smith
{:cust-name Sue Jones, :cust-address 43 Rose Court Street, :cust-phone 345-7867}

Answer 1

您的代码中有许多错误，与缺乏基本的 clojure 知识有关：

1) 不要在函数内部使用def/defn，而是使用let

2) 添加到地图通常使用assoc

3) 从函数中返回一些重要的值，并在外部进行自省总是更好。

我会以更 clojure 的方式重写您的函数，如下所示： （我有意保留 placeholder 参数，虽然它没有在您的代码中的任何地方使用，所以我无法推断它的目的）

(defn read-customer-file [input-list new-map placeholder]
  (if-let [[[id name address phone] & input-tail] (seq input-list)]
    (read-customer-file input-tail
                        (assoc new-map (keyword id)
                               {:cust-name name
                                :cust-address address
                                :cust-phone phone})
                        ())
    new-map))

在回复中：

user> (read-customer-file [["a" "b" "c" "d"] ["e" "f" "g" "h"]] {} ())
;;=> {:a {:cust-name "b", :cust-address "c", :cust-phone "d"},
;;    :e {:cust-name "f", :cust-address "g", :cust-phone "h"}}

但您真正需要的是一些更高阶的数据处理功能，例如 map:

(defn read-customer-file [input-list placeholder]
  (into {}
        (map (fn [[id name address phone]]
               [(keyword id) {:cust-name name
                              :cust-phone phone
                              :cust-address address}])
             input-list)))

user> (read-customer-file [["a" "b" "c" "d"] ["e" "f" "g" "h"]] {})
;;=> {:a {:cust-name "b", :cust-phone "d", :cust-address "c"},
;;    :e {:cust-name "f", :cust-phone "h", :cust-address "g"}}

或reduce:

(defn read-customer-file [input-list placeholder]
  (reduce (fn [res [id name address phone]]
            (assoc res (keyword id) {:cust-name name
                                     :cust-phone phone
                                     :cust-address address}))
          {} input-list))

此外，将您的业务逻辑（在您的案例文件记录到客户转换中）抽象为一些专门的功能总是一个好主意，以保持处理功能更通用：

(defn file-rec->customer [[id name address phone]]
  [(keyword id) {:cust-name name
                 :cust-address address
                 :cust-phone phone}])

(defn read-data-file [record-processor input-list placeholder]
  (into {} (map record-processor) input-list))

user> (read-data-file file-rec->customer [["a" "b" "c" "d"] ["e" "f" "g" "h"]] {})
;;=> {:a {:cust-name "b", :cust-address "c", :cust-phone "d"},
;;    :e {:cust-name "f", :cust-address "g", :cust-phone "h"}}

Answer 2

我能够通过在返回时将其转换为排序地图来解决问题。此外，返回的值再次被转换为一个排序映射，这可以解决问题。请查看更新部分。