使用 UTF8 编码的 IdHTTPServer 和 IdHTTP

Question

我正在使用TIdHTTPServer 和TIdHTTP 测试本地主机服务器。我在编码 UTF8 数据时遇到问题。

客户端：

procedure TForm1.SpeedButton1Click(Sender: TObject);
var
  res: string;
begin
  res:=IdHTTP1.Get('http://localhost/?msg=đi chơi thôi');
  Memo1.Lines.Add(res);
end;

服务器端：

procedure TForm1.OnCommandGet(AContext: TIdContext;
  ARequestInfo: TIdHTTPRequestInfo; AResponseInfo: TIdHTTPResponseInfo);
begin
  Memo1.Lines.Add(ARequestInfo.Params.Values['msg']); // ?i ch?i th?i

  AResponseInfo.CharSet := 'utf-8';
  AResponseInfo.ContentText := 'chào các bạn'; // chào các b?n
end;

我想发送đi chơi thôi 并接收chào các bạn。但是服务器接收?i ch?i th?i，客户端接收chào các b?n。

谁能帮帮我？

Answer 1

TIdHTTP 完全按照您提供的方式传输 URL，但 http://localhost/?msg=đi chơi thôi 不是可以按原样传输的有效 URL，因为 URL 只能包含 ASCII 字符。未保留的 ASCII 字符可以按原样使用，但保留和非 ASCII 字符必须以字符集编码为字节，然后这些字节必须以%HH 格式进行 url 编码，例如：

IdHTTP1.Get('http://localhost/?msg=%C4%91i%20ch%C6%A1i%20th%C3%B4i');

您必须确保仅将有效的 url 编码 URL 传递给 TIdHTTP。

在此示例中，URL 是硬编码的，但如果您需要更动态的内容，请使用 TIdURI 类，例如：

IdHTTP1.Get('http://localhost/?msg=' + TIdURI.ParamsEncode('đi chơi thôi'));

TIdHTTPServer 然后将按照您的预期解码参数数据。 TIdURI 和 TIdHTTPServer 默认使用 UTF-8。

发送响应时，您只是设置了CharSet，但没有设置ContentType。所以TIdHTTPServer 会将ContentType 设置为'text/html; charset=ISO-8859-1'，覆盖你的CharSet。您需要自己显式设置ContentType，以便您可以指定自定义CharSet，例如：

AResponseInfo.ContentType := 'text/plain';
AResponseInfo.CharSet := 'utf-8';
AResponseInfo.ContentText := 'chào các bạn';

或者：

AResponseInfo.ContentType := 'text/plain; charset=utf-8';
AResponseInfo.ContentText := 'chào các bạn';

---

附带说明，TIdHTTPServer 是一个多线程组件。 OnCommand... 事件在工作线程的上下文中触发，而不是在主 UI 线程中触发。所以像你一样直接访问Memo1 不是线程安全的。您必须与主 UI 线程同步才能安全地访问 UI 控件，例如：

procedure TForm1.OnCommandGet(AContext: TIdContext; ARequestInfo: TIdHTTPRequestInfo; AResponseInfo: TIdHTTPResponseInfo);
var
  msg: string;
begin
  msg := ARequestInfo.Params.Values['msg'];
  TThread.Synchronize(nil,
    procedure
    begin
      Memo1.Lines.Add(msg);
    end
  );
  ...
end;