我如何理解 Haskell 中的“:t ((==) <*>)”？

Question

我是 Haskell 的新手，在这里遇到<*> 的麻烦：

((==) <*>) :: Eq a => (a -> a) -> a -> Bool

我如何理解这一点以及如何推断？

Answer 1

免责声明：这不是惯用的 Haskell 代码。

优先考虑的是<*> 的“运算符部分”。当您看到一个运算符仅应用于一个称为部分的参数时。下面是一个更常见的运算符部分的示例：

(1 +) :: Int -> Int

这是一个将+ 部分应用于 1 的函数，为最后一个参数留出空间。相当于：

\x -> 1 + x

因此，在您的代码示例中，<*> 部分应用于 (==)，因此我们将其扩展为：

((==) <*>)

= \g -> (==) <*> g

接下来你需要了解<*> 在做什么。这是Applicative 类型类的成员：

class (Functor f) => Applicative f where
    pure  :: a -> f a
    (<*>) :: f (a -> b) -> f a -> f b

这意味着<*> 被重载以适用于实现Applicative 的任何类型。 Applicative 类型的一个实例是((->) r)：

instance Applicative ((->) r) where
    pure  :: a -> ((->) r) a
    (<*>) :: (->) r (a -> b) -> (->) r a -> (->) r b

(->) 周围的括号表示以前缀形式使用（在定义像这样的类实例时，出于语法原因，这是必要的）。如果将其扩展为中缀形式，则会得到：

instance Applicative ((->) r) where
    pure  :: a -> r -> a
    (<*>) :: (r -> a -> b) -> (r -> a) -> (r -> b)

在您的具体示例中，<*> 的第一个参数是 (==) 运算符，它具有以下类型：

(==) :: Eq e => e -> e -> Bool

因此，如果我们将其传递给(<*>)，编译器可以在(<*>) 的签名中推断出更多关于r、a 和b 的类型：

 (<*>) ::        (r -> a -> b   ) -> (r -> a) -> (r -> b)
 (==)  :: Eq e => e -> e -> Bool
                  |    |    |
                  |    |    +-> `b` must be `Bool`
                  |    |
                  |    +------> `a` must be `e`
                  |
                  +-----------> `r` must also be `e`

所以当我们提供(==) 作为(<*>) 的第一个参数时，我们会得到这个推断类型：

((==) <*>) :: Eq e => (e -> e) -> (e -> Bool)

您可以省略右括号，因为(->) 是右结合的，并将e 更改为a 以给出您得到的最终签名：

((==) <*>) :: Eq a => (a -> a) -> a -> Bool

但这实际上在做什么？要了解我们需要了解(<*>) 是如何为((->) r) 的Applicative 实例定义的：

(f <*> g) r = f r (g r)

如果我们将f 替换为(==)，我们会得到：

((==) <*> g) r = (==) r (g r)

当我们用括号括住(==) 时，这意味着我们在前缀符号中使用它。这意味着如果我们删除括号并将其改回中缀符号，我们会得到：

((==) <*> g) r = r == (g r)

这相当于：

((==) <*>) = \g r -> r == g r

也就是说你的函数有两个参数：g和r，然后看看r是否等于g r。