快速拖放许多精灵实例之一

Question

我在拖放功能和对象选择方面遇到问题。

我创建了简单的 flash 编曲器（将表格图标添加到舞台 - 房间）。我有创建表格图标新实例的按钮，我可以在舞台上拖放。

问题是我只能拖放最后添加的图标。如果我添加新的实例 od 图标，我将无法获取（拖放）之前创建的任何图标：/

我的代码在这里：主类

import flash.events.MouseEvent;
import flash.events.Event;
import com.adobe.images.JPGEncoder;
import flash.geom.Point;

btn_middleTable.addEventListener(MouseEvent.CLICK, f_middleIco);
btn_bigTable.addEventListener(MouseEvent.CLICK, f_bigIco);
btnSave.addEventListener(MouseEvent.CLICK, f_save);

function f_middleIco(event:MouseEvent):void
{
    var middle:MiddleIco = new MiddleIco();
    middle.x = 20;
    middle.y = 20;
    stage.addChild(middle);
    trace("created");
}

function f_bigIco(event:MouseEvent):void
{
    var big:BigIco = new BigIco();
    big.x = 20;
    big.y = 20;
    stage.addChild(big);
    trace("created");
}

function f_save(event:MouseEvent)
{
    var jpgEncoder:JPGEncoder;
    jpgEncoder = new JPGEncoder(90);

    var bitmapData:BitmapData = new BitmapData(stage.width, stage.height);
    bitmapData.draw(stage, new Matrix());
    var img = jpgEncoder.encode(bitmapData);

    var file:FileReference = new FileReference();
    file.save(img, "filename.png");
}

图标实例包：

package  {

    import flash.display.MovieClip;
    import flash.events.MouseEvent;
    import flash.events.Event;
    import flash.geom.Point;

    public class BigIco extends MovieClip {
            public var active:Boolean;

        public function BigIco() {
            // constructor code
            this.addEventListener(Event.ENTER_FRAME, f_move);
            this.addEventListener(MouseEvent.MOUSE_DOWN,downf);
            this.addEventListener(MouseEvent.MOUSE_UP,upf);
        }

        public function f_move(e:Event)
        {
            if(active==true)
            {
                startDrag();
            }
            else if(active==false)
            {
                stopDrag();
            }
        }

        public function downf(e:MouseEvent)
        {
            active = true;
        }
        public function upf(e:MouseEvent)
        {
            active = false;
        }
}
}

我该怎么做才能选择实际上在鼠标光标上的每个图标（实例）？

Answer 1

理论：startDrag 和 stopDrag 并不意味着被重复调用 - 但它们会在每一帧，对于您添加的每个剪辑都会调用一次，因为您使用的是 ENTER_FRAME 侦听器。

我尚未对此进行测试，但调用 stopDrag 实际上可能会停止任何拖动 - 包括在其他剪辑上 - 因为你是 only allowed to drag a single Sprite (and hence MovieClip) in the first place。

因此，如果该理论成立，您的第一个图标上的startDrag() 将立即被新图标上的f_move() 取消调用stopDrag()。

但是无论如何你都不需要ENTER_FRAME 监听器。这应该给出相同的结果（除了它实际上有效） - 只需立即在鼠标侦听器中调用拖动方法：

public class BigIco extends MovieClip {
    public var active:Boolean;

    public function BigIco() {
        // constructor code
        this.addEventListener(MouseEvent.MOUSE_DOWN, downf);
        this.addEventListener(MouseEvent.MOUSE_UP, upf);
    }

    public function downf(e:MouseEvent)
    {
        // Unless you're going to use 'active' for other stuff,
        // you can remove this line:
        active = true; 
        startDrag();
    }
    public function upf(e:MouseEvent)
    {
        // Same here:
        active = false;
        stopDrag();
    }
}

除此之外，我无法在您的代码中发现任何真正的问题。

编辑：“完美”版本，如果指针不在图标上方，也会检测鼠标向上：

public class BigIco extends MovieClip {

    public function BigIco() {
        // Only add mouse down listener here. We'll add up when needed below:
        this.addEventListener(MouseEvent.MOUSE_DOWN,downf);
    }

    public function downf(e:MouseEvent)
    {
        // Add event listener to stage, so as to be triggered even if
        // the pointer isn't over the icon when releasing the button.
        // Note that this will also work even with the mouse *outside*
        // the stage/swf area:
        stage.addEventListener(MouseEvent.MOUSE_UP,upf);
        startDrag();
    }
    public function upf(e:MouseEvent)
    {
        // Remember to remove the event listener after use:
        stage.removeEventListener(MouseEvent.MOUSE_UP, upf);
        stopDrag();
    }
}