在 F# 中编写这些方法的函数式方法

Question

为了计算正方形和圆形的面积，我定义了以下类型：

type Square = {width: float; length: float;} with
    member this.area = this.width * this.length
    member this.perimeter = (this.width + this.length) * 2.

type Circle = {r:float} with 
    member this.area = System.Math.PI * this.r * this.r
    member this.perimeter = 2. * System.Math.PI * this.r

let s1 = {width = 3.; length = 4.}
let c1 = {r = 8.3}

printfn "%A" s1
printfn "The area of s1 is: %A" s1.area
printfn "The perimeter of s1 is: %A" s1.perimeter


printfn "%A" c1
printfn "The area of c1 is: %A" c1.area
printfn "The perimeter of c1 is: %A" c1.perimeter

当我读到这篇文章时： http://fsharpforfunandprofit.com/posts/type-extensions/

它说：

• 方法不能很好地用于类型推断
• 方法不能很好地处理高阶函数

所以，恳请那些刚接触函数式编程的人。不要使用 如果可以的话，尤其是在你学习的时候。他们是 一个拐杖会阻止你从功能中获得全部好处 编程。

那么解决这个问题的函数式方法是什么？或者什么是惯用的 F# 方式？

---

编辑：

在阅读了“F# 组件设计指南”（对@V.B. 屈膝）和@JacquesB 的评论之后，我认为在类型中实现成员方法是最简单、内在的方式：

type Square2 (width: float, length: float) =
    member this.area = width * length
    member this.perimeter = (width + length) * 2.

（这与我原来的Square 类型几乎相同——这个Square2 只保存了几个this. 前缀，如this.width、this.length。）

同样，The F# Component Design Guidelines 非常有用。

Answer 1

更实用的方法是创建一个Shape 可区分联合，其中Square 和Circle 就是它的情况。然后创建函数area 和perimeter，取Shape 并使用模式匹配：

type Shape =
    | Square of Width: float * Length: float
    | Circle of R: float

let area = function
    | Square (width, length) -> width * length
    | Circle r -> System.Math.PI * r * r

let perimeter = function
    | Square (width, length) -> (width + length) * 2.
    | Circle r -> 2. * System.Math.PI * r

let s1 = Square(Width = 3., Length = 4.)
let c1 = Circle(R = 8.3)

printfn "%A" s1
printfn "The area of s1 is: %A" (area s1)
printfn "The perimeter of s1 is: %A" (perimeter s1)


printfn "%A" c1
printfn "The area of c1 is: %A" (area c1)
printfn "The perimeter of c1 is: %A" (perimeter c1)

Answer 2

@svick 很好地描述了一种更实用的方式，但也可以考虑 "The F# Component Design Guidelines"

• 对类型固有的操作使用属性和方法。

之所以这么叫，是因为有些人来自职能部门 编程背景避免使用面向对象编程 一起，更喜欢一个包含一组定义函数的模块 与类型相关的内在函数（例如长度 foo 而不是 foo.Length）。但另请参阅下一个项目符号。一般来说，在 F# 中，使用 面向对象的编程是首选的软件工程 设备。该策略还提供了一些工具优势，例如 Visual Studio 的“Intellisense”功能可发现 通过“打点”一个对象来输入。

• 考虑使用接口类型来表示可能以多种方式实现的相关操作组。

在 F# 中有多种方式来表示 操作，例如使用函数元组或函数记录。 一般来说，我们建议您为此目的使用接口类型。

因此，根据这些准则，尽管通常有一种“功能更强大”的方式，但带有 Area 和 Perimeter 成员的接口 IShape 是 F# 组件的推荐方式。