用 Haskell 编码“小于”

Question

我希望一些 Haskell 专家可以帮助澄清一些事情。

是否可以以通常的方式定义Nat（通过@dorchard Singleton types in Haskell）

data S n = Succ n 
data Z   = Zero

class Nat n 
instance Nat Z
instance Nat n => Nat (S n)

（或其一些变体），然后定义LessThan 关系 这样对于所有n 和m

LessThan Z (S Z)
LessThan n m => LessThan n     (S m)
LessThan n m => LessThan (S n) (S m)

然后编写一个类型如下的函数：

foo :: exists n. (LessThan n m) => Nat m -> Nat n
foo (S n) = n
foo Z     = foo Z

我明确想在foo 的输出类型中使用“LessThan”， 我意识到一个人当然可以写出类似

的东西

foo :: Nat (S n) -> Nat n

但这不是我想要的。

谢谢！

兰吉特。

Answer 1

这是实现类似于您所询问的内容的一种方法。

自然

首先请注意，您将Nat 定义为一个类，然后将其用作一个类型。我认为将它作为一种类型是有意义的，所以让我们这样定义它。

data Z
data S n

data Nat n where
  Zero :: Nat Z
  Succ :: Nat n -> Nat (S n)

小于

我们也可以将LessThan定义为一个类型。

data LessThan n m where
  LT1 :: LessThan Z (S Z)
  LT2 :: LessThan n m -> LessThan n (S m)
  LT3 :: LessThan n m -> LessThan (S n) (S m)

请注意，我只是将您的三个属性转换为数据构造函数。这种类型的想法是，LessThan n m 类型的完全标准化值是 n 小于 m 的证明。

存在主义的变通方法

现在你问：

foo :: exists n. (LessThan n m) => Nat m -> Nat n

但在 Haskell 中不存在。相反，我们可以为foo 定义一个数据类型：

data Foo m where
  Foo :: Nat n -> LessThan n m -> Foo m

请注意，n 在这里被有效地量化了，因为它出现在数据构造函数 Foo 的参数中，但没有出现在其结果中。现在我们可以声明foo的类型了：

foo :: Nat m -> Foo m

引理

在我们实现问题中的示例之前，我们必须证明一个关于LessThan 的小引理。引理说对于所有n，n 小于S n。我们通过对n 的归纳来证明这一点。

lemma :: Nat n -> LessThan n (S n)
lemma Zero = LT1
lemma (Succ n) = LT3 (lemma n)

foo 的实现

现在我们可以编写问题中的代码了：

foo :: Nat m -> Foo m
foo (Succ n) = Foo n (lemma n)
foo Zero = foo Zero