TCL列表数据转直方图

Question

我正在做一些数据分析，输出是一长串数字。每行由 1 到 n 个数字组成，可以重复：

1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 2 2 2 2 2 2 2 2 3 3 4

我想将它们放入（时间序列）直方图中。我不是 tcl 方面的专家（还不是？），我有一些想法如何做到这一点，但我还没有成功。 puts 语句只是为了让我可以看到正在发生的事情。

---

while { [gets $infile line] != -1 } {
    set m [llength $line]
    puts "line length $m"
    foreach item $line {
        puts $item
        incr nc($item)
        puts "nc: $nc($item)"
    }
}

我创建的这个 nc 数组是给了我一个基于大小的数组。但是，我想要一个基于每行的数组（2D）。天真地它会是 nc($item)($nlines)。我最初尝试用 nc${item}($nlines) 等长度标记数组变量，但我不够聪明，无法让它工作。

感谢您的帮助。 最好的 迈克

Answer 1

虽然 Tcl 数组是一维的，但你可以构造关键字符串来伪造多维：

set lineno -1
set fh [open infile r]

while {[gets $fh line] != -1} {
    incr lineno
    foreach item [split [string trim $line]] {
        incr nc($lineno,$item)
    }
}
close $fh

# `parray` is a handy command for inspecting arrays
parray nc

输出

nc(0,1) = 20
nc(0,2) = 8
nc(0,3) = 2
nc(0,4) = 1
nc(1,1) = 2
nc(1,2) = 4
nc(1,4) = 3
nc(2,1) = 1
nc(2,2) = 1
nc(2,3) = 1
nc(2,4) = 1

或者使用字典：

set lineno -1
set nc {}
set fh [open infile r]

while {[gets $fh line] != -1} {
    set thisLine {}
    foreach item [split [string trim $line]] {
        dict incr thisLine $item
    }
    dict set nc [incr lineno] $thisLine
}
close $fh

dict for {line data} $nc {
    puts [list $line $data]
}

输出

0 {1 20 2 8 3 2 4 1}
1 {1 2 2 4 4 3}
2 {1 1 2 1 3 1 4 1}