为什么这个接口委托会导致内存泄漏？答案

【问题标题】：Why is this interface delegation causing memory leak?为什么这个接口委托会导致内存泄漏？
【发布时间】：2020-01-02 14:52:33
【问题描述】：

假设我有以下代码

单元TalkerIntf.pas

unit TalkerIntf;

interface

{$MODE OBJFPC}

type

    ITalker = interface
        ['{95E1FAE3-7495-4404-AE88-6A7DB88383EC}']
        procedure say() ;
    end;

implementation
end.

单元TalkerImpl.pas

unit TalkerImpl;

interface

{$MODE OBJFPC}

uses

    TalkerIntf;

type

    TTalker = class(TInterfacedObject, ITalker)
    public
        procedure say();
    end;

implementation

    procedure TTalker.say();
    begin
        writeln('Hello');
    end;

end.

单元DelegateTalkerImpl.pas

unit DelegateTalkerImpl;

interface

{$MODE OBJFPC}

uses

    TalkerIntf;

type

    TDelegateTalker = class(TInterfacedObject, ITalker)
    private
        fActualTalker : ITalker;
    public
        constructor create(const talker : ITalker);
        destructor destroy(); override;

        property talker : ITalker read fActualTalker implements ITalker;
    end;

implementation

    constructor TDelegateTalker.create(const talker : ITalker);
    begin
        fActualTalker := talker;
    end;

    destructor TDelegateTalker.destroy();
    begin
        fActualTalker := nil;
        inherited destroy();
    end;

end.

和程序 memleak.pas

program memleak;

{$MODE OBJFPC}

uses

    TalkerIntf,
    TalkerImpl,
    DelegateTalkerImpl;

var
    talker : ITalker;

begin
    talker := TDelegateTalker.create(TTalker.create());
    talker.say();
end.

在 (-gh) 上使用 FreePascal 3.0.4 和 heaptrc 进行编译，heaptrc 报告存在内存泄漏

$ fpc -gh memleak.pas
$ ./memleak

Heaptrc 输出

Hello
Heap dump by heaptrc unit
2 memory blocks allocated : 64/64
0 memory blocks freed     : 0/0
2 unfreed memory blocks : 64
True heap size : 32768
True free heap : 32384
Should be : 32448
Call trace for block $00007FA0D7846180 size 32
$000000000040020F
Call trace for block $00007FA0D78460C0 size 32

为什么这个接口委托会导致内存泄漏？如何避免？

Original post

更新

似乎唯一的解决方法是删除 implements 并手动进行委派。以下代码不会出现内存泄漏。

unit DelegateTalkerImpl;

interface

{$MODE OBJFPC}

uses

    TalkerIntf;

type

    TDelegateTalker = class(TInterfacedObject, ITalker)
    private
        fActualTalker : ITalker;
    public
        constructor create(const talker : ITalker);
        destructor destroy(); override;

        procedure say();
    end;

implementation

    constructor TDelegateTalker.create(const talker : ITalker);
    begin
        fActualTalker := talker;
    end;

    destructor TDelegateTalker.destroy();
    begin
        fActualTalker := nil;
        inherited destroy();
    end;

    procedure TDelegateTalker.say();
    begin
        fActualTalker.say();
    end;
end.

【问题讨论】：

我认为这是 fpc 复制了一个长期存在的 Delphi 错误，似乎永远无法修复。 stackoverflow.com/questions/31028266 stackoverflow.com/questions/7640841 stackoverflow.com/questions/22846335

标签： memory-leaks freepascal

【解决方案1】：

根据ASerge's comment

将变量定义为 ITalker 时，不会返回新创建的对象，而只会返回实现它的字段。结果，一个新创建的对象被泄露。 Delphi 的行为是一样的。

为了避免内存泄漏但仍然使用implements关键字，我们需要分配给ITalker以外类型的临时变量，然后将其类型转换为ITalker。

var
    talker : ITalker;
    delegateTalker : IInterface;

begin
    delegateTalker := TDelegateTalker.create(TTalker.create());
    talker := delegateTalker as ITalker;
    talker.say();
end.

【讨论】：